Formatting quirk

[Rob_Holman]

Hi folks:

I'm trying to make a Manipulate cell that shows some sigma notation in traditional form, and that has updating text above it.

Here is some code without the text. Everything looks just like I want it, with the exception of the missing text up top. It'd be nice to get the overscript "k" to change in the sigma notation, but no big deal:

_______

TraditionalForm[
Manipulate[
Row[{HoldForm[Sum[(-1)^n/2^n, {n, 0, Style["k", Italic]}]], " = ",
Sum[(-1)^n/2^n, {n, 0, k}], " = ",
N[Sum[(-1)^n/2^n, {n, 0, k}], 20]}], {k, 1, 40, 1}]]
_________

Now, in the next code I've added a snippet of text above, and that screws up the display of the traditional form for some reason:
_________

TraditionalForm[
Manipulate[
Column[{
Row[{"Adding up ", ToString[k], " terms:"}],
" ",
Row[{HoldForm[Sum[(-1)^n/2^n, {n, 0, Style["k", Italic]}]], " = ",
Sum[(-1)^n/2^n, {n, 0, k}], " = ",
N[Sum[(-1)^n/2^n, {n, 0, k}], 20]}]
}], {k, 1, 15, 1}]]
___________

Among other things, I have tried putting the Sigma notation in a Pane that is plenty tall enough to allow the full traditional form, and that didn't work.

Anyone have any good ideas about this? I've tried five or six different things to no avail.

Thanks,

Rob

[Michael_Morrison]

Hi Rob,

The Column command has a default setting that automatically shrinks the typesetting for things like Sum, Product, and Integrate. If we turn this behavior off, you'll get result you're looking for:

TraditionalForm[
Manipulate[
Column[{Row[{"Adding up ", ToString[k], " terms:"}], " ",
Row[{HoldForm[Sum[(-1)^n/2^n, {n, 0, Style["k", Italic]}]], " = ",
Sum[(-1)^n/2^n, {n, 0, k}], " = ",
N[Sum[(-1)^n/2^n, {n, 0, k}], 20]}]},
AllowScriptLevelChange -> False], {k, 1, 15, 1}]]

More information about that option here: http://reference.wolfram.com/mathematic ... hange.html

Thanks,
Michael