Generate exercises with a button?

[Rob_Holman]

Hi all:

I've made some code that generates arbitrary factorable quadratics, and displays the solutions when clicked. It's below:
_______________
(* Coefficient Functions *)
factor[x_] := RandomInteger[{1, 5}];
factor2[x_] := RandomInteger[{-5, 5}];

(* Generating the random exercises *)
table1 = Table[{
Row[{n, ". "}],
Expand[(s = (factor[n] x + factor2[n]))*(s1 = (factor[n] x +
factor2[n]))] // TraditionalForm, " = ",
s* s1 // TraditionalForm}, {n, 1, 10}];

FlipView[{
(* Answers Hidden *)

Style[Grid[table1, ItemStyle -> {{-1 -> White}, Automatic},
Dividers -> {{True, False, False, False, True}, All},
Spacings -> {1, 1.5}], FontFamily -> Times],

(* Answers Shown *)

Style[Grid[table1, ItemStyle -> {{-1 -> Blue}, Automatic},
Dividers -> {{True, False, False, False, True}, All},
Spacings -> {1, 1.5}], FontFamily -> Times]

}]
_________________

Now, what I'd like to do is make a CDF out of this with a button a the top, where the students could regenerate a new list of 10 if they would like to do so. How can I do that?

Thanks!

Rob

[Michael_Morrison]

Rob,

Do you want to only display one set of exercises at a time, or do you want clicking the button to generate a new set of exercises but not override the previous set? If it's the latter, this is very simple: just use Button, give it a label, and for the second argument, copy and paste your code inside a set of parentheses, and add //Print to the end of the second argument. There are two example files here:
http://members.wolfram.com/mmorrison/FacultyProgram.html

The first is a notebook with all of the code, the second is a CDF, without code, but which has the button and is still functional.

Hope that helps,
-Michael

[Rob_Holman]

What I ended up doing is making a Manipulate panel with the ContinuousAction set to None. Thus, the parameters can be changed, and a new batch of exercises isn't constructed until the update icon (U in the top right) is clicked.

Now... for the icing on the cake, is there a way to embed a more obvious button in the gray upper part of the Manipulate panel that will do the same thing as that little "U" icon? I'd love to have a big "Generate Exercises" button sitting below the input fields.

Code is below -- and thanks for the help!

Rob

_______________


Manipulate[

(*Coefficient Functions*)

factor[x_] := RandomInteger[{minlead, maxlead}];
factor2[x_] := RandomInteger[{minconst, maxconst}];

(*Generating the random exercises*)

table1 =
Table[{Row[{n, ". "}],
Expand[(s = (factor[n] x + factor2[n]))*(s1 = (factor[n] x +
factor2[n]))] // TraditionalForm, " = ",
s*s1 // TraditionalForm}, {n, 1, exer}];

FlipView[{

(*Answers Hidden*)
Style[Grid[table1, ItemStyle -> {{-1 -> White}, Automatic},
Dividers -> {{True, False, False, False, True}, All},
Spacings -> {1, 1.5}], FontFamily -> Times],

(*Answers Shown*)
Style[Grid[table1, ItemStyle -> {{-1 -> Blue}, Automatic},
Dividers -> {{True, False, False, False, True}, All},
Spacings -> {1, 1.5}], FontFamily -> Times]}],

{{exer, 10, "Number of Exercises"}, {10, 15, 20}}, {{minlead, 1,
"Minimum Factor Lead Coefficient"}, InputField},
{{maxlead, 3, "Maximum Factor Lead Coefficient"}, InputField},
{{minconst, -5, "Minimum Factor Constant Term"}, InputField},
{{maxconst, 5, "Maximum Factor Constant Term"}, InputField},
TrackedSymbols -> All, ContinuousAction -> None, Alignment -> Center
]

[Michael_Rogers]

Normally, I insert a dummy variable in the Manipulate expression and bump the value when the button is pressed. The change in value triggers an update if the variable is tracked. In your case, it would be the only tracked variable. Rough idea:

Manipulate[generate; (* dummy statement, for dependency *)
StringForm["Exercise set ``", x], {x, 0, 1}, {{generate, 0}, None},
Button["Generate Exercises", generate++],
TrackedSymbols :> {generate}]

However, in your particular code, you can use table1, instead of inserting a new dummy variable. I stuck the exercise set generating code in a new function, GenerateExercises[]. (Note: ContinuousAction -> None should be omitted below.)


Manipulate[(*Coefficient Functions*)(*Generating the random exercises*)
FlipView[{(*Answers Hidden*)
Style[Grid[table1, ItemStyle -> {{-1 -> White}, Automatic},
Dividers -> {{True, False, False, False, True}, All},
Spacings -> {1, 1.5}], FontFamily -> Times],(*Answers Shown*)
Style[Grid[table1, ItemStyle -> {{-1 -> Blue}, Automatic},
Dividers -> {{True, False, False, False, True}, All},
Spacings -> {1, 1.5}], FontFamily -> Times]}], {{exer, 10,
"Number of Exercises"}, {10, 15, 20}},
{{minlead, 1, "Minimum Factor Lead Coefficient"}, InputField},
{{maxlead, 3, "Maximum Factor Lead Coefficient"}, InputField},
{{minconst, -5, "Minimum Factor Constant Term"}, InputField},
{{maxconst, 5, "Maximum Factor Constant Term"}, InputField},
(*{{table1,{}},None},*)

Button["Generate Exercises", GenerateExercises[]],
TrackedSymbols :> {table1}, Alignment -> Center,
Initialization :> (factor[x_] := RandomInteger[{minlead, maxlead}];
factor2[x_] := RandomInteger[{minconst, maxconst}];
GenerateExercises[] := (table1 =
Table[{Row[{n, ". "}],
Expand[(s = (factor[n] x + factor2[n]))*(s1 = (factor[n] x +
factor2[n]))] // TraditionalForm, " = ",
s*s1 // TraditionalForm}, {n, 1, exer}]);
GenerateExercises[])]

Cheers,
Michael