Wolfram Language

Probabilité et statistiques étendues

Densité de probabilité pour produits / quotients de variables aléatoires

Trouvez la fonction de densité de probabilité pour le plus petit rapport au plus grand échantillon parmi les n dessins indépendants de BetaDistribution[2, 3].

In[1]:=
Click for copyable input
n = 5; pdf = PDF[ TransformedDistribution[ min/max, {min, max} \[Distributed] OrderDistribution[{BetaDistribution[2, 3], n}, {1, n}]], u]
Out[1]=

Visualisez la densité.

In[2]:=
Click for copyable input
Plot[pdf, {u, 0, 1}, PlotRange -> All, Filling -> Axis, PlotTheme -> "Detailed", ImageSize -> Medium, PlotLegends -> None]
Out[2]=

Calculez la densité de probabilité pour le produit de deux distributions triangulaires.

In[3]:=
Click for copyable input
pdf2 = PDF[ TransformedDistribution[ x1 x2, {x1 \[Distributed] TriangularDistribution[{-1, 2}, -1], x2 \[Distributed] TriangularDistribution[{-4, 3}, 2]}], u]
Out[3]=
Montrer l'entrée complète de Wolfram Language
In[4]:=
Click for copyable input
Plot[pdf2, {u, -4, 4}, Exclusions -> None, Filling -> Axis, PlotTheme -> "Detailed", ImageSize -> "Medium", PlotLegends -> None, PlotRange -> All]
Out[4]=

Trouvez la densité de probabilité pour le quotient de deux variables aléatoires normales indépendantes.

In[5]:=
Click for copyable input
pdf3 = PDF[ TransformedDistribution[ z1/z2, {z1 \[Distributed] NormalDistribution[], z2 \[Distributed] NormalDistribution[\[Mu], 1]}], x]
Out[5]=

La distribution est à queue lourde pour toute valeur fixe de .

In[6]:=
Click for copyable input
Series[Exp[\[Mu]^2/2] pdf3, {x, Infinity, 8}, Assumptions -> \[Mu] > 0] // Expand
Out[6]=
Montrer l'entrée complète de Wolfram Language
In[7]:=
Click for copyable input
Plot[Evaluate[ pdf3 /. {{\[Mu] -> 0}, {\[Mu] -> 1}, {\[Mu] -> 3}, {\[Mu] -> 5}}], {x, -2, 2}, PlotLegends -> {"\[Mu] = 0", "\[Mu] = 1", "\[Mu] = 3", "\[Mu] = 5"}, PlotRange -> All, PlotTheme -> "Detailed", ImageSize -> "Medium"]
Out[7]=

Exemples connexes

de en es ja ko pt-br ru zh