Wolfram Language

Geodätische Berechnung

Wie schwer ist es?

Das Gewicht eines Objekts in einem Gravitationsfeld ist das Produkt seiner Masse und der herrschenden Gravitationskraft. Auf der Erdoberfläche ist die Gravitationskraft nicht konstant, daher ist dasselbe Objekt an unterschiedlichen Orten unterschiedlich schwer. Dieses Beispiel befasst sich mit den durch Höhe und Breitengrad bedingten Schwankungen der Gravitationsfeldstärke.

GeogravityModelData berechnet Eigenschaften des Gravitationsfelds der Erde an einem bestimmten Ort.

In[1]:=
Click for copyable input
GeogravityModelData[GeoPosition[{0, 0}]]
Out[1]=

Die dazu verwendeten topographischen Höhendaten stammen von GeoElevationData.

In[2]:=
Click for copyable input
GeoElevationData[GeoPosition[{0, 0}]]
Out[2]=

Lässt man andere Faktoren beiseite, ist das Gravitationsfeld an einem Ort mit ähnlichem Breitengrad, der aber höher gelegen ist, normalerweise kleiner.

In[3]:=
Click for copyable input
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]
Out[3]=
In[4]:=
Click for copyable input
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]; {GeoElevationData[%, UnitSystem -> "Metric"], GeogravityModelData[%, "Magnitude"]}
Out[4]=

Berechnen Sie die Stärke des Gravitationsfeldes an Äquator-äquidistanten Punkten.

In[5]:=
Click for copyable input
equatorialgravity = GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{0, 180}]}, "Magnitude"][[1]]
Out[5]=
In[6]:=
Click for copyable input
ListPlot[equatorialgravity, Joined -> True]
Out[6]=

Das Diagramm zeigt zwei ausgeprägte Spitzen, die der Landmasse und den Meeresgründen der Ozeane entsprechen.

In[7]:=
Click for copyable input
Histogram[equatorialgravity, 20]
Out[7]=

Veranschaulichen Sie die Stärke des Gravitationsfeldes in einer Reliefkarte der Erde.

In[8]:=
Click for copyable input
equatorialgravityplot = ListPlot[equatorialgravity, Axes -> False, Joined -> True, AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None, ImageSize -> 400, PlotStyle -> Red];
In[9]:=
Click for copyable input
worldmap = GeoGraphics[GeoPath["Equator"], GeoRange -> "World", ImageSize -> 400, GeoBackground -> "ReliefMap"];
In[10]:=
Click for copyable input
Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]
Out[10]=

Um die Stärkenschwankung des Gravitationsfeldes je nach Breitengrad zu verdeutlichen, nehmen wir den jeweiligen Durchschnittswert der Gravitationsfeldstärke der Längengrade und stellen das Ergebnis in Bezug auf Breitengrade dar.

In[11]:=
Click for copyable input
gravity = Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}], GeoPosition[{90, 180}]}, "Magnitude"];

Die Antarktis macht sich augfrund der Höhe ihrer durchgehenden Landmasse in den niedrigen Breitengraden bemerkbar.

In[12]:=
Click for copyable input
ListPlot[gravity, DataRange -> {-90, 90}]
Out[12]=
In[13]:=
Click for copyable input
MinMax[gravity]
Out[13]=

Daher kann das Gewicht eines beliebigen Objekts um 0,5% schwanken, abhängig davon, wo wir es messen.

In[14]:=
Click for copyable input
MinMax[gravity]; 1 - First[%]/Last[%]
Out[14]=

Verwandte Beispiele

en es fr ja ko pt-br ru zh