Wolfram Language

Calcul géographique

Combien cela pèse-t-il?

Le poids d'un objet dans un champ gravitationnel est le produit de sa masse et la valeur du champ gravitationnel au point de l'objet. Sur la surface de la Terre, le champ de gravitation n'est pas constante, et par conséquent le même objet pèse différemment à différents endroits. Cet exemple explore la variabilité de magnitude du champ de gravitation en élévation et en latitude.

GeogravityModelData calcule plusieurs propriétés du champ gravitationnel de la Terre à un endroit donné.

In[1]:=
Click for copyable input
GeogravityModelData[GeoPosition[{0, 0}]]
Out[1]=

Il utilise l'élévation topographique fournie par GeoElevationData.

In[2]:=
Click for copyable input
GeoElevationData[GeoPosition[{0, 0}]]
Out[2]=

En ignorant d'autres effets, le champ gravitationnel est généralement plus faible pour un en endroit avec la même latitude, mais avec une plus haute altitude.

In[3]:=
Click for copyable input
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]
Out[3]=
In[4]:=
Click for copyable input
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]; {GeoElevationData[%, UnitSystem -> "Metric"], GeogravityModelData[%, "Magnitude"]}
Out[4]=

Calculez les valeurs de la magnitude du champ gravitationnel à des points équidistants sur l'équateur.

In[5]:=
Click for copyable input
equatorialgravity = GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{0, 180}]}, "Magnitude"][[1]]
Out[5]=
In[6]:=
Click for copyable input
ListPlot[equatorialgravity, Joined -> True]
Out[6]=

Dans l'histogramme suivant, il y a deux pics principaux, correspondant aux zones terrestres et au fond des océans.

In[7]:=
Click for copyable input
Histogram[equatorialgravity, 20]
Out[7]=

Superposez la magnitude du champ gravitationnel sur une carte du relief de la Terre.

In[8]:=
Click for copyable input
equatorialgravityplot = ListPlot[equatorialgravity, Axes -> False, Joined -> True, AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None, ImageSize -> 400, PlotStyle -> Red];
In[9]:=
Click for copyable input
worldmap = GeoGraphics[GeoPath["Equator"], GeoRange -> "World", ImageSize -> 400, GeoBackground -> "ReliefMap"];
In[10]:=
Click for copyable input
Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]
Out[10]=

Pour montrer la variabilité avec la latitude, nous prenons la moyenne de la magnitude du champ de gravité sur la longitude, et nous représentons le résultat par rapport à la latitude.

In[11]:=
Click for copyable input
gravity = Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}], GeoPosition[{90, 180}]}, "Magnitude"];

L'Antarctique a un effet évident pour les basses latitudes, en raison de l'élévation ajoutée.

In[12]:=
Click for copyable input
ListPlot[gravity, DataRange -> {-90, 90}]
Out[12]=
In[13]:=
Click for copyable input
MinMax[gravity]
Out[13]=

Par conséquent, il peut y avoir des changements de l'ordre de 0,5% du poids d'un objet donné, selon l'endroit où nous le mesurons.

In[14]:=
Click for copyable input
MinMax[gravity]; 1 - First[%]/Last[%]
Out[14]=

Exemples connexes

de en es ja ko pt-br ru zh