Язык Wolfram Language

Георасчёты

Сколько это весит?

Вес объекта в гравитационном поле является произведением его массы и значением гравитационного поля в положении объекта. Гравитационное поле не является постоянным на поверхности Земли, поэтому один и тот же объект имеет различную массу в различных положениях.

Данный пример изучает изменения масштаба гравитационного поля с высотой и широтой.

GeogravityModelData рассчитывает несколько свойств гравитационного поля Земли в заданном положении.

In[1]:=
Click for copyable input
GeogravityModelData[GeoPosition[{0, 0}]]
Out[1]=

А также использует топографическую высоту, предоставленную GeoElevationData.

In[2]:=
Click for copyable input
GeoElevationData[GeoPosition[{0, 0}]]
Out[2]=

Если не принимать во внимание другие факторы, то гравитационное поле обычно меньше для положения со схожей широтой, но большей высотой.

In[3]:=
Click for copyable input
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]
Out[3]=
In[4]:=
Click for copyable input
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]; {GeoElevationData[%, UnitSystem -> "Metric"], GeogravityModelData[%, "Magnitude"]}
Out[4]=

Рассчитайте значения гравитационного поля Земли на равноудалённых точках на экваторе.

In[5]:=
Click for copyable input
equatorialgravity = GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{0, 180}]}, "Magnitude"][[1]]
Out[5]=
In[6]:=
Click for copyable input
ListPlot[equatorialgravity, Joined -> True]
Out[6]=

В предложенной гистограмме Вы найдёте две главные вершины, соответствующие земным областям и дну океанов.

In[7]:=
Click for copyable input
Histogram[equatorialgravity, 20]
Out[7]=

Наложите масштаб гравитационного поля на рельефную карту Земли.

In[8]:=
Click for copyable input
equatorialgravityplot = ListPlot[equatorialgravity, Axes -> False, Joined -> True, AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None, ImageSize -> 400, PlotStyle -> Red];
In[9]:=
Click for copyable input
worldmap = GeoGraphics[GeoPath["Equator"], GeoRange -> "World", ImageSize -> 400, GeoBackground -> "ReliefMap"];
In[10]:=
Click for copyable input
Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]
Out[10]=

С целью демонстрации изменений широты найдите среднее значение гравитационного поля по отношению к долготе и представьте результат в отношении широты.

In[11]:=
Click for copyable input
gravity = Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}], GeoPosition[{90, 180}]}, "Magnitude"];

Антарктика находится под очевидным влиянием низких широт из-за дополнительной высоты.

In[12]:=
Click for copyable input
ListPlot[gravity, DataRange -> {-90, 90}]
Out[12]=
In[13]:=
Click for copyable input
MinMax[gravity]
Out[13]=

Таким образом, отклонения в весе определённого объекта могут достигать порядка 0.5% в зависимости от места измерения.

In[14]:=
Click for copyable input
MinMax[gravity]; 1 - First[%]/Last[%]
Out[14]=

Родственные примеры

de en es fr ja ko pt-br zh