Wolfram Language

Machiche Learning amélioré

Trouvez les paramètres optimaux d'un classifieur

Chargez un ensemble de données et divisez-le en un ensemble d'entraînement et un ensemble de test.

In[1]:=
Click for copyable input
data = RandomSample[ ExampleData[{"MachineLearning", "Titanic"}, "Data"] ]; training = data[[;; 1000]]; test = data[[1001 ;;]];

Définissez une fonction de calcul de la performance d'un classifieur en fonction de ses (hyper)paramètres.

In[2]:=
Click for copyable input
loss[{c_, gamma_, b_, d_}] := -ClassifierMeasurements[ Classify[training, Method -> {"SupportVectorMachine", "KernelType" -> "Polynomial", "SoftMarginParameter" -> Exp[c], "GammaScalingParameter" -> Exp[gamma], "BiasParameter" -> Exp[b], "PolynomialDegree" -> d } ], test, "LogLikelihoodRate"];

Définissez la valeur possible des paramètres avec une région.

In[3]:=
Click for copyable input
region = ImplicitRegion[And[ -3. <= c <= 3., -3. <= gamma <= 3. , -1. <= b <= 2., 1 <= d <= 3 , d \[Element] Integers], { c, gamma, b, d}]
Out[3]=

Recherchez un bon ensemble de paramètres.

In[4]:=
Click for copyable input
bmo = BayesianMinimization[loss, region]
Out[4]=
In[5]:=
Click for copyable input
bmo["MinimumConfiguration"]
Out[5]=

Entraînez un classifieur avec ces paramètres.

In[6]:=
Click for copyable input
Classify[training, Method -> {"SupportVectorMachine", "KernelType" -> "Polynomial", "SoftMarginParameter" -> Exp[2.979837222482109`], "GammaScalingParameter" -> Exp[-2.1506497693543025`], "BiasParameter" -> Exp[-0.9038364134482837`], "PolynomialDegree" -> 2} ]
Out[6]=

Exemples connexes

de en es ja ko pt-br ru zh