Wolfram Language

Expansion de la base de connaissance

Générez une visite à pied de bâtiments remarquables

Utilisez GeoNearest pour récupérer les bâtiments remarquables dans un rayon de 1 km autour de Boston City Hall.

In[1]:=
Click for copyable input
position = Entity["Building", "BostonCityHall::96t3t"]; radius = Quantity[1, "Kilometers"];
In[2]:=
Click for copyable input
nearMe = GeoNearest["Building", position, {All, radius}]
Out[2]=

Tracez ces bâtiments sur une carte locale en utilisant des entités d'icônes intégrées.

Montrer l'entrée complète de Wolfram Language
In[3]:=
Click for copyable input
iconItemPairs = With[{icon = EntityValue[Entity["Icon", "Museum"], "Image"][[1]]}, MapThread[{#1, Graphics[{EdgeForm[Black], FaceForm[#2], icon}, "ImageSize" -> 25]} &, {nearMe, RandomColor[Length@nearMe]}] ]; legend = Column[ Row[Reverse@#] & /@ (MapAt[CommonName, #, 1] & /@ iconItemPairs)]; Row[{ GeoGraphics[{EdgeForm[Darker[Orange]], Orange, GeoDisk[position, radius], GeoMarker[position, "Color" -> Red], GeoMarker @@@ iconItemPairs}, ImageSize -> 400], legend }]
Out[3]=

Utilisez TravelDirections pour calculer une visite à pied de ces entités.

In[4]:=
Click for copyable input
tourPlaces = Prepend[nearMe, position];
In[5]:=
Click for copyable input
{distance, tourPath} = FindShortestTour[GeoPosition /@ tourPlaces, 1, Length@tourPlaces]
Out[5]=
In[6]:=
Click for copyable input
travelDirectionsForPath = TravelDirections[tourPlaces[[tourPath]], TravelMethod -> "Walking"]
Out[6]=
Montrer l'entrée complète de Wolfram Language
In[7]:=
Click for copyable input
Row[{ GeoGraphics[{ Thickness[0.01], Darker@Red, GeoPath@travelDirectionsForPath, EdgeForm[Darker[Orange]], Orange, GeoDisk[position, radius], GeoMarker[position, "Color" -> Red], GeoMarker @@@ iconItemPairs }, ImageSize -> 400], legend }]
Out[7]=

Voici des instructions détaillées sur la façon de suivre cette voie.

In[8]:=
Click for copyable input
travelDirectionsForPath["ManeuverGrid"]
Out[8]=

Exemples connexes

de en es ja ko pt-br ru zh