Wolfram Language

Équations aux dérivées partielles

Modélisez le flux de chaleur dans une barre isolée

Modélisez le flux de chaleur dans une barre de longueur 1 isolée aux deux extrémités.

In[1]:=
Click for copyable input
heqn = D[u[x, t], t] == D[u[x, t], {x, 2}];

Indiquez qu'il n'y ait aucune chaleur à travers les extrémités de la barre.

In[2]:=
Click for copyable input
bc = {Derivative[1, 0][u][0, t] == 0, Derivative[1, 0][u][1, t] == 0};

Spécifiez une condition initiale.

In[3]:=
Click for copyable input
ic = u[x, 0] == 20 + 80 x;

Résolvez l'équation de chaleur sous ces conditions .

In[4]:=
Click for copyable input
sol = DSolve[{heqn, bc, ic}, u[x, t], {x, t}]
Out[4]=

Extrayez quelques termes de la somme Inactive.

In[5]:=
Click for copyable input
approxsol = u[x, t] /. sol[[1]] /. {Infinity -> 4} // Activate // Expand
Out[5]=

Visualisez l'évolution de la température à la valeur à l'état stable de 60°.

In[6]:=
Click for copyable input
Plot[Table[approxsol, {t, 0.02, 0.9, 0.07}] // Evaluate, {x, 0, 1}, AxesOrigin -> {0, 0}, PlotRange -> All]
Out[6]=

Exemples connexes

de en es ja ko pt-br ru zh