Wolfram Language

Équations aux dérivées partielles

Observez une particule quantique dans une boîte

Une particule quantique libre pour se déplacer à l'intérieur d'un rectangle à deux dimensions avec des côtés xMax et yMax est décrite par l'équation de Schrödinger bidimensionnelle en fonction du temps ainsi que des conditions aux limites qui forcent la fonction d'onde à zéro à la frontière.

In[1]:=
Click for copyable input
eqn = I D[\[Psi][x, y, t], t] == -\[HBar]^2/(2 m) Laplacian[\[Psi][x, y, t], {x, y}];
In[2]:=
Click for copyable input
bcs = {\[Psi][0, y, t] == 0, \[Psi][xMax, y, t] == 0, \[Psi][x, yMax, t] == 0, \[Psi][x, 0, t] == 0};

Cette équation a une solution générale qui est une somme infinie formelle de ce qu'on appelle les états propres.

In[3]:=
Click for copyable input
DSolveValue[{eqn, bcs}, \[Psi][x, y, t], {x, y, t}]
Out[3]=

Définissez une condition initiale égale à un état propre.

In[4]:=
Click for copyable input
initEigen = \[Psi][x, y, 0] == 2 /Sqrt[xMax yMax] Sin[(\[Pi] x)/xMax] Sin[(\[Pi] y)/yMax];

Dans ce cas, la solution est tout simplement un multiple en fonction du temps (de l'unité module) de l'état initial.

In[5]:=
Click for copyable input
DSolveValue[{eqn, bcs, initEigen}, \[Psi][x, y, t], {x, y, t}]
Out[5]=

Définissez une condition initiale qui est une somme d'états propres. Du fait que les conditions initiales ne sont pas un état propre, la densité de probabilité de la localisation de la particule sera dépendante du temps.

In[6]:=
Click for copyable input
initSum = \[Psi][x, y, 0] == Sqrt[2]/Sqrt[ xMax yMax] (Sin[(2 \[Pi] x)/xMax] Sin[(\[Pi] y)/yMax] + Sin[(\[Pi] x)/xMax] Sin[(3 \[Pi] y)/yMax]);

Résolvez avec la nouvelle condition initiale.

In[7]:=
Click for copyable input
sol = DSolveValue[{eqn, bcs, initSum}, \[Psi][x, y, t], {x, y, t}]
Out[7]=

Calculez la densité de probabilité, l'insertion des valeurs de masse constante, d'électrons de la réduction de Planck, et une boîte de taille atomique, en utilisant des unités de la masse d'électrons, nanomètres et femtosecondes.

In[8]:=
Click for copyable input
\[HBar] = QuantityMagnitude[Quantity[1., "ReducedPlanckConstant"], "ElectronMass" * ("Nanometers")^2/"Femtoseconds"]
Out[8]=
In[9]:=
Click for copyable input
\[Rho][x_, y_, t_] = FullSimplify[ComplexExpand[Conjugate[sol] sol]] /. {m -> 1, xMax -> 1, yMax -> 1}
Out[9]=

Visualisez la densité de probabilité à l'intérieur de la boîte dans le temps.

In[10]:=
Click for copyable input
ListAnimate[ Table[Plot3D[\[Rho][x , y , t], {x, 0, 1}, {y, 0, 1}, PlotTheme -> {"Scientific", "SolidGrid"}, AxesLabel -> {"\!\(\* StyleBox[\"x\", \"SO\"]\) (nm)", " \!\(\* StyleBox[\"y\", \"SO\"]\) (nm)", "\!\(\* StyleBox[\"\[Rho]\", \"SO\"]\) (\!\(\*SuperscriptBox[\(nm\), \ \(-2\)]\))"}, ImageSize -> Medium, PlotRange -> {0, 7}], {t, 0, 19, .5}]]
Jouer l'animation
Arrêter l'annimation

Exemples connexes

de en es ja ko pt-br ru zh