Wolfram Language

Équations aux dérivées partielles

Étudiez les vibrations d'une corde tendue

Étudiez les vibrations d'une corde tendue en utilisant l'équation d'onde.

In[1]:=
Click for copyable input
weqn = D[u[x, t], {t, 2}] == D[u[x, t], {x, 2}];

Précisez que les extrémités de la chaîne restent fixes pendant les vibrations.

In[2]:=
Click for copyable input
bc = {u[0, t] == 0, u[\[Pi], t] == 0};

Donnez des valeurs initiales à différents points de la chaîne.

In[3]:=
Click for copyable input
ic = {u[x, 0] == x^2 (\[Pi] - x), \!\(\*SuperscriptBox[\(u\), TagBox[ RowBox[{"(", RowBox[{"0", ",", "1"}], ")"}], Derivative], MultilineFunction->None]\)[x, 0] == 0};

Résolvez le problème à valeur de limite initiale.

In[4]:=
Click for copyable input
dsol = DSolve[{weqn, bc, ic}, u, {x, t}] /. {K[1] -> m}
Out[4]=

Extrayez quatre termes de la somme Inactive.

In[5]:=
Click for copyable input
asol[x_, t_] = u[x, t] /. dsol[[1]] /. {\[Infinity] -> 4} // Activate
Out[5]=

Chaque terme de la somme représente une onde stationnaire.

In[6]:=
Click for copyable input
Table[Show[ Plot[Table[asol[x, t][[m]], {t, 0, 4}] // Evaluate, {x, 0, Pi}, Ticks -> False], ImageSize -> 150], {m, 4}]
Out[6]=

Visualisez la vibration de la chaîne.

In[7]:=
Click for copyable input
Animate[Plot[asol[x, t], {x, 0, \[Pi]}, PlotRange -> {-5, 5}, ImageSize -> Medium, PlotStyle -> Red], {t, 0, 2 Pi}, SaveDefinitions -> True]
Jouer l'animation
Arrêter l'annimation

Exemples connexes

de en es ja ko pt-br ru zh