Wolfram Language

Medidas em probabilidade e estatística

Reatores nucleares

NuclearReactorData fornece dados sobre os reatores nucleares conhecidos em todo o mundo. Alguns deles já foram desativados, como Chernobyl. Você pode selecionar os reatores que estão ativos atualmente para a análise dos recursos energéticos nucleares.

In[1]:=
Click for copyable input
reactors = NuclearReactorData[];
In[2]:=
Click for copyable input
active = Select[reactors, #["Status"] == "operational" &];

Extraia a produção de energia anual e o país em que se encontra.

In[3]:=
Click for copyable input
annualproduction = NuclearReactorData[active, "AnnualEnergyProduction"]; countries = Map[First, NuclearReactorData[active, "Countries"]];

Crie um conjunto de dados e remova os pontos de dados que contêm valores que estejam faltando. O número de rectores em funcionamento é acima de 400.

In[4]:=
Click for copyable input
data = Transpose[{active, countries, annualproduction}]; data = DeleteMissing[data, 1, 2];
In[5]:=
Click for copyable input
data // Dimensions
Out[5]=

O número de reatores por país.

In[6]:=
Click for copyable input
percountry = GroupBy[data, #1[[2]] &];
In[7]:=
Click for copyable input
numberpercountry = Map[Length, percountry];
In[8]:=
Click for copyable input
BarChart[Sort[numberpercountry], ChartLabels -> Automatic, ChartStyle -> "DarkRainbow", BarOrigin -> Left, BarSpacing -> 1, LabelingFunction -> (Placed[#1, After] &), ImageSize -> Large]
Out[8]=

O número de reatores corresponde ao total de energia nuclear produzida por país.

In[9]:=
Click for copyable input
energytotals = Map[Total[#[[All, 3]]] &, percountry];
In[10]:=
Click for copyable input
stats = {Min, Max, Mean, Median, Total}; TableForm[#[energytotals] & /@ stats, TableHeadings -> {stats}]
Out[10]//TableForm=

Os maiores produtores de energia nuclear são os Estados Unidos e a França.

In[11]:=
Click for copyable input
TakeLargest[energytotals, 2]
Out[11]=
mostre o input completo da Wolfram Language
In[12]:=
Click for copyable input
GeoRegionValuePlot[energytotals, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]
Out[12]=

O mapa parecerá diferente se você considerar a produção total de energia per capita. Use CountryData para acessar totais das populações de cada país na lista.

In[13]:=
Click for copyable input
populations = AssociationThread[Keys[energytotals], CountryData[#, "Population"] & /@ Keys[energytotals]];

Calcule a energia nuclear per capita.

In[14]:=
Click for copyable input
energypercapita = energytotals/populations;
In[15]:=
Click for copyable input
TableForm[#[energypercapita] & /@ stats, TableHeadings -> {stats}]
Out[15]//TableForm=

No mapa, você pode ver que mesmo os EUA tendo a maior produção de energia nuclear absoluta, não é a maior por pessoa, enquanto a França e a Suécia têm a liderança.

In[16]:=
Click for copyable input
TakeLargest[energypercapita, 2]
Out[16]=
mostre o input completo da Wolfram Language
In[17]:=
Click for copyable input
GeoRegionValuePlot[energypercapita, GeoProjection -> "Mercator", GeoRange -> {{-70, 80}, {-170, 190}}, GeoLabels -> (Tooltip[#1, #2] &)]
Out[17]=

Exemplos Relacionados

de en es fr ja ko ru zh