Wolfram Language

Matrices aléatoires

Ensembles circulaires (COE, CUE, ...)

Les ensembles circulaires sont des familles de matrices unitaires avec différentes distributions invariantes par transformations unitaires. Les applications typiques sont en mécanique statistique, théorie des nombres, combinatoire et la physique nucléaire.

Les matrices d'un ensemble circulaire (CRE) sont orthogonales. »

In[1]:=
Click for copyable input
cre = RandomVariate[CircularRealMatrixDistribution[5]];
In[2]:=
Click for copyable input
OrthogonalMatrixQ[cre]
Out[2]=

Les matrices circulaires de l'ensemble unitaire (CUE) sont unitaires. »

In[3]:=
Click for copyable input
cue = RandomVariate[CircularUnitaryMatrixDistribution[5]];
In[4]:=
Click for copyable input
UnitaryMatrixQ[cue]
Out[4]=

Les matrices circulaires de l'ensemble orthogonal (CE) sont symétriques et unitaires. »

In[5]:=
Click for copyable input
coe = RandomVariate[CircularOrthogonalMatrixDistribution[5]];
In[6]:=
Click for copyable input
SymmetricMatrixQ[coe] && UnitaryMatrixQ[coe]
Out[6]=

Les matrices d'un ensemble symplectique circulaire (CSE) sont quaternions unitaires auto-duals. »

Montrer l'entrée complète de Wolfram Language
In[7]:=
Click for copyable input
selfdualQuaternionicQ[m_] := With[{\[ScriptCapitalJ] = KroneckerProduct[{{0, -1}, {1, 0}}, IdentityMatrix[Length[m]/2]], mat = SetAccuracy[m, 10]}, Transpose[mat].\[ScriptCapitalJ] == \[ScriptCapitalJ].mat];
In[8]:=
Click for copyable input
cse = RandomVariate[CircularSymplecticMatrixDistribution[5]];
In[9]:=
Click for copyable input
UnitaryMatrixQ[cse] && selfdualQuaternionicQ[cse]
Out[9]=

Les matrices circulaires ensemble du quaternion (CQE) sont symplectique unitaire. »

Montrer l'entrée complète de Wolfram Language
In[10]:=
Click for copyable input
symplecticMatrixQ[mat_] := With[{\[ScriptCapitalJ] = KroneckerProduct[{{0, -1}, {1, 0}}, IdentityMatrix[Length[mat]/2]] }, Conjugate[mat].\[ScriptCapitalJ] == \[ScriptCapitalJ].mat];
In[11]:=
Click for copyable input
cqe = RandomVariate[CircularQuaternionMatrixDistribution[5]];
In[12]:=
Click for copyable input
UnitaryMatrixQ[cqe] && symplecticMatrixQ[cqe]
Out[12]=

Les valeurs de matrices de CUE, COE, et le CST ont une longueur de l'unité et sont réparties uniformément en phase.

Montrer l'entrée complète de Wolfram Language
In[13]:=
Click for copyable input
args = Flatten[ Arg[RandomVariate[ MatrixPropertyDistribution[Eigenvalues[x], x \[Distributed] #], 10^4]]] & /@ {CircularUnitaryMatrixDistribution[5], CircularOrthogonalMatrixDistribution[5], CircularSymplecticMatrixDistribution[5]}; Row[MapThread[ Histogram[#1, {-Pi, Pi, Pi/10}, Frame -> None, ChartLegends -> Placed[#2, Above]] &, {args, {Style["Unitary", 15], Style["Orthogonal", 15], Style["Symplectic", 15]}}]]
Out[13]=

Visualisez la distribution conjointe de la phase des valeurs propres à deux dimensions d'une CUE et comparez-la avec la densité actuelle.

In[14]:=
Click for copyable input
evs\[ScriptCapitalD] = MatrixPropertyDistribution[Arg[Eigenvalues[x]], x \[Distributed] CircularUnitaryMatrixDistribution[2]]; \[CurlyPhi]s = RandomSample /@ RandomVariate[evs\[ScriptCapitalD], 10^5];
Montrer l'entrée complète de Wolfram Language
In[14]:=
Click for copyable input
Show[ Histogram3D[\[CurlyPhi]s, {-Pi, Pi, 0.25}, PDF, PlotTheme -> "Scientific", ChartStyle -> "AvocadoColors"], Plot3D[1/(8 Pi^2) Abs[Exp[I \[Phi]1] - Exp[I \[Phi]2]]^2, {\[Phi]1, -Pi, Pi}, {\[Phi]2, -Pi, Pi}, PlotStyle -> None, MeshStyle -> Thick], ImageSize -> Medium]
Out[15]=

Exemples connexes

de en es ja ko pt-br ru zh