Wolfram Language

Matrices aléatoires

Plus longues sous-séquences croissantes

Le nombre de permutations d'éléments dans lesquels la sous-séquence croissante la plus longue est dans la partie de la longueur , peut être calculée au moyen de , où sont des matrices extraites de CircularUnitaryMatrixDistribution de dimension .

In[1]:=
Click for copyable input
{k, n} = {6, 2};

Définissez la distribution de propriétés de la matrice et calculez la moyenne.

In[2]:=
Click for copyable input
\[ScriptCapitalD] = MatrixPropertyDistribution[Abs[Tr[\[ScriptCapitalU]]]^( 2 k), \[ScriptCapitalU] \[Distributed] CircularUnitaryMatrixDistribution[n]]; N[Mean[\[ScriptCapitalD]]]
Out[2]=

Comparez avec le comptage direct.

In[3]:=
Click for copyable input
Count[Permutations[Range[k]], perm_ /; Length[LongestOrderedSequence[perm]] <= n]
Out[3]=

Pour ,la distribution des longueurs d'échelle de la plus longue augmentation sous-séquences de permutations aléatoires converge vers la distribution TracyWidom .

In[4]:=
Click for copyable input
sample[n_] := 1/n^(1/6) (Table[ Length[LongestOrderedSequence[ RandomSample[Range[n]]]], {2000}] - 2.0 Sqrt[n]);

Comparez l'histogramme lisse de longueurs d'échelle échantillonnées pour augmenter les dimensions avec la fonction de densité de probabilité de la distribution de TracyWidom.

Montrer l'entrée complète de Wolfram Language
In[5]:=
Click for copyable input
dims = {1000, 5000, 10000}; Show[ SmoothHistogram[sample /@ dims, PlotLegends -> (Row[{"n = ", #}] & /@ dims)], Plot[PDF[TracyWidomDistribution[2], x], {x, -4, 2}, PlotStyle -> {Black, Dashed, Thick}, PlotLegends -> {"Tracy-Widom distribution"}]]
Out[5]=

Exemples connexes

de en es ja ko pt-br ru zh