Wolfram Language

Matrices aléatoires

La distribution de MarchenkoPastur

La distribution de MarchenkoPastur est la distribution de limite des valeurs propres de matrices de Wishart comme la matrice de dimension m et degrés de liberté n les deux tendent à l'infini avec le rapport . Pour , la distribution n'a pas de masse ponctuelle et la fonction de densité de probabilité est bien définie.

In[1]:=
Click for copyable input
PDF[MarchenkoPasturDistribution[1/2], x]
Out[1]=
Montrer l'entrée complète de Wolfram Language
In[2]:=
Click for copyable input
Plot[PDF[MarchenkoPasturDistribution[1/2], x], {x, 0, 3}, PlotRange -> All, Exclusions -> None, Filling -> Axis, PlotTheme -> "Detailed", ImageSize -> Medium, PlotLegends -> None]
Out[2]=

Échantillon d'une distribution de Wishart avec matrice d'échelle d'identité et calculez les valeurs propres à l'échelle.

In[3]:=
Click for copyable input
n = 10^4; m = 10^3; eigs = RandomVariate[ MatrixPropertyDistribution[Eigenvalues[x]/n, x \[Distributed] WishartMatrixDistribution[n, IdentityMatrix[m]]]];

Comparez le résultat échantillonné avec la fonction de densité de MarchenkoPastur.

In[4]:=
Click for copyable input
Show[Histogram[eigs, {0.05}, "PDF", ImageSize -> Medium, PlotTheme -> "Detailed"], Plot[PDF[MarchenkoPasturDistribution[m/n], x], {x, 0, 1.8}, PlotTheme -> "Detailed", PlotLegends -> None, Exclusions -> None]]
Out[4]=

Pour , la matrice de Wishart est singulière. La probabilité , la distribution a une masse dans le point .

In[5]:=
Click for copyable input
m = 500; n = 2 m; CDF[MarchenkoPasturDistribution[n/m], 0]
Out[5]=

Générez une matrice avec covariance d'identité et calculez avec les valeurs propres à l'échelle.

In[6]:=
Click for copyable input
matrix = Transpose[#].# &[RandomVariate[NormalDistribution[], {m, n}]]; eigvs = Chop[Eigenvalues[matrix]/m];

Il y a une lacune dans la densité des valeurs propres proches de 0, et le conteneur 0 a une grande densité.

In[7]:=
Click for copyable input
Histogram[eigvs, {0.05}, PDF, PlotRange -> 1, ChartStyle -> Orange, ImageSize -> Medium]
Out[7]=

Ajustez MarchenkoPasturDistribution aux valeurs propres.

In[8]:=
Click for copyable input
edist = EstimatedDistribution[eigvs, MarchenkoPasturDistribution[\[Lambda], 1]]
Out[8]=

La fonction de distribution d'accumulation de la distribution ajustée montre une discontinuité de saut à l'origine.

Montrer l'entrée complète de Wolfram Language
In[9]:=
Click for copyable input
Show[Histogram[eigvs, {0.05}, CDF, ChartStyle -> Orange], Quiet@Plot[CDF[edist, x], {x, -1.5, 5.75}, Exclusions -> None, PlotStyle -> Thick], ImageSize -> Medium, AxesOrigin -> {-1, 0}, PlotRange -> {{-1.5, 6}, {0, 1}}]
Out[9]=

Exemples connexes

de en es ja ko pt-br ru zh