Wolfram Language

Matrices aléatoires

Distributions de matrice normale et la matrice T

Les distributions de matrice normale et de matrice t matrice sont des distributions normales et T avec échelle de ligne et des matrices de colonnes spécifié. L'utilisation typique comprend l'analyse des séries chronologiques, des processus aléatoires, et régression multivariée.

Étant donné les matrices d'échelle Σrow et Σcol, la distribution normale de matrice a une densité de probabilité proportionnelle à . Échantillon d'une matrice de distribution normale.

In[1]:=
Click for copyable input
Subscript[\[CapitalSigma], row] = {{1, 0.9}, {0.9, 1}}; Subscript[\[CapitalSigma], col] = {{1, -0.9}, {-0.9, 1}};
In[2]:=
Click for copyable input
RandomVariate[ MatrixNormalDistribution[Subscript[\[CapitalSigma], row], Subscript[\[CapitalSigma], col]]]
Out[2]=

Visualisez les vecteurs lignes échantillonnées sur un diagramme de dispersion et de la comparer avec la fonction de densité.

In[3]:=
Click for copyable input
sample = RandomVariate[ MatrixNormalDistribution[Subscript[\[CapitalSigma], row], Subscript[\[CapitalSigma], col]], 10^4]; firstrows = sample[[All, 1]];
Montrer l'entrée complète de Wolfram Language
In[4]:=
Click for copyable input
Show[ContourPlot[ PDF[MultinormalDistribution[{0, 0}, Subscript[\[CapitalSigma], col] ], {x, y}], {x, -4.5, 4.5}, {y, -4.5, 4.5}, PlotPoints -> 30, PlotTheme -> "Detailed", ImageSize -> Medium], ListPlot[firstrows, ImageSize -> Medium, PlotTheme -> "Detailed", PlotStyle -> Black]]
Out[4]=

Visualisez les vecteurs de colonnes échantillonnées sur un histogramme et comparez-les avec la fonction de densité.

In[5]:=
Click for copyable input
firstcols = sample[[All, All, 1]];
Montrer l'entrée complète de Wolfram Language
In[6]:=
Click for copyable input
Show[Histogram3D[firstcols, Automatic, "PDF", ImageSize -> Medium, PlotTheme -> "Detailed", ChartStyle -> "Pastel"], Plot3D[PDF[ MultinormalDistribution[{0, 0}, Subscript[\[CapitalSigma], row] ], {x, y}], {x, -5, 5}, {y, -5, 5}, PlotRange -> All, ImageSize -> Medium, PlotTheme -> "Detailed", PlotLegends -> None]]
Out[6]=

Semblable aux distributions t de Student et t multivariée, la distribution t de matrice est un mélange de distribution normale de matrice avec un paramètre d'échelle de distribution inverse de Wishart. Exemple d'une distribution t de matrice.

In[7]:=
Click for copyable input
RandomVariate[ MatrixTDistribution[Subscript[\[CapitalSigma], row], Subscript[\[CapitalSigma], col], 3]]
Out[7]=

Générez un ensemble de matrices distribuées de matrice t.

In[8]:=
Click for copyable input
sample = RandomVariate[ MatrixTDistribution[Subscript[\[CapitalSigma], row], Subscript[\[CapitalSigma], col], 3], 10^4];

Les projections de dimension inférieure de variables distribués avec la matrice t sont des distributions de t de Student et de t multivariée. Projetez l'échantillon à des vecteurs à deux dimensions et vérifiez la qualité de l'ajustement.

In[9]:=
Click for copyable input
v = {1, 2}; vecs = sample.v;
In[10]:=
Click for copyable input
DistributionFitTest[vecs, MultivariateTDistribution[ Subscript[\[CapitalSigma], row] (v.Subscript[\[CapitalSigma], col].v)/3, 3]]
Out[10]=

Visualisez les données projetées sur un diagramme de dispersion et comparez-les avec la fonction de densité.

Montrer l'entrée complète de Wolfram Language
In[11]:=
Click for copyable input
Show[ContourPlot[ PDF[MultivariateTDistribution[ Subscript[\[CapitalSigma], row] (v.Subscript[\[CapitalSigma], col].v)/3, 3], {x, y}], {x, -5, 5}, {y, -5, 5}, PlotPoints -> 30, PlotTheme -> "Detailed", ImageSize -> Medium], ListPlot[vecs, ImageSize -> Medium, PlotTheme -> "Detailed", PlotStyle -> Black]]
Out[11]=

Exemples connexes

de en es ja ko pt-br ru zh