Wolfram Language

Matrices aléatoires

Distribution de TracyWidom

La distribution de TracyWidom est une distribution limite de la plus grande valeur propre d'une échelle des ensembles de matrices aléatoires appartenant à des ensembles de Gauss. En outre, il apparaît dans différents domaines, tels que des problèmes de comptage, les modèles de croissance aléatoires, des transitions de phase, etc., et donne des prévisions précises.

La distribution de TracyWidom est composée de trois classes = 1, 2 et 4. Chacune correspond à différents ensembles de Gauss; découvrez la fonction correspondante de densité de probabilité.

Montrer l'entrée complète de Wolfram Language
In[1]:=
Click for copyable input
Plot[Table[ PDF[TracyWidomDistribution[\[Beta]], x], {\[Beta], {1, 2, 4}}] // Evaluate, {x, -5, 2}, Filling -> Axis, PlotLegends -> {"\[Beta] = 1", "\[Beta] = 2", "\[Beta] = 4"}, ImageSize -> Medium, PlotTheme -> "Detailed"]
Out[1]=

Utilisez MatrixPropertyDistribution pour représenter la valeur propre d'échelle la plus grande d'une matrice de GUE.

In[2]:=
Click for copyable input
ev\[ScriptCapitalD][2, n_] := MatrixPropertyDistribution[(Max[Eigenvalues[x]] - 2 Sqrt[n]) n^(1/6), x \[Distributed] GaussianUnitaryMatrixDistribution[n]]

Échantillon de la distribution et comparez l'histogramme avec la fonction de densité de probabilité.

In[3]:=
Click for copyable input
sample = RandomVariate[ev\[ScriptCapitalD][2, 250], 2000];
Montrer l'entrée complète de Wolfram Language
In[4]:=
Click for copyable input
Show[Histogram[sample, {0.2}, PDF, PlotTheme -> "Detailed"], Plot[PDF[TracyWidomDistribution[2], x ], {x, -5, 2}, PlotStyle -> Thick, PlotTheme -> "Detailed", PlotLegends -> None], ImageSize -> Medium]
Out[4]=

La distribution TracyWidom peut être bien approchée par une distribution gamma dans la région centrale.

In[5]:=
Click for copyable input
gdist = GammaDistribution[k, s, 1, a]; PDF[gdist, x]
Out[5]=

Ajustez la distribution gamma avec la distribution TracyWidom de = 1 en faisant correspondre les trois premiers moments.

In[6]:=
Click for copyable input
moments = Through[{Mean, Variance, Skewness}[gdist]]; nmoments = N[Through[{Mean, Variance, Skewness}[TracyWidomDistribution[1]]]]; sol = FindRoot[Thread[moments == nmoments], {{k, 1}, {s, 1}, {a, 1}}]
Out[6]=

Comparez les fonctions de densité de probabilité.

Montrer l'entrée complète de Wolfram Language
In[7]:=
Click for copyable input
Plot[{PDF[gdist /. sol, x], PDF[TracyWidomDistribution[1], x]} // Evaluate, {x, -5, 2}, PlotLegends -> {"Gamma distribution", "Tracy-Widom distribution"}, Filling -> Axis, PlotTheme -> "Detailed", ImageSize -> Medium]
Out[7]=

Exemples connexes

de en es ja ko pt-br ru zh