Wolfram Language

Acesso mais produtivo à base de conhecimento

Crie uma EntityStore de meteoros de bola de fogo

A Wolfram Knowledgebase contém uma grande quantidade de informações que abrange diversas áreas. Ele também possui um poderoso conjunto de recursos para representar, acessar e realizar cálculos com este conhecimento. Agora também é possível (e até mesmo simples) para usuários criarem seus próprios conjuntos de dados e trabalhar com eles como se fossem dados integrados. Aqui, o processo de criação e uso de um banco de dados de entidade para meteoritos bola de fogo (conhecidos como bólidos) com base em uma fonte de dados existente é ilustrado.

Use Import para fazer o download de um conjunto de dados de bólidos mantido pelo Jet Propulsion Laboratory.

In[1]:=
Click for copyable input
(rawdata = Import["http://neo.jpl.nasa.gov/fireballs/", "FullData"])[[3, 9, 2, 12, 1, ;; 5]]
Out[1]=

Defina uma função de utilidade para adicionar unidades aos dados brutos.

In[2]:=
Click for copyable input
AddUnits[x_, u_: "Kilometers"/"Seconds"] := If[NumberQ[x], Quantity[Interpreter["Number"][x], u], Missing["NotAvailable"]]

Extraia partes relevantes dos dados, adicione uma identificação apropriada de Quantity, e crie o banco de dados entidades.

mostre o input completo da Wolfram Language
In[3]:=
Click for copyable input
bolidedata = DeleteCases[{ DateObject[#1], With[{i = Interpreter["GeoCoordinates"][#2 <> " " <> #3]}, If[Head[i] === Missing, i, GeoPosition[Join[i[[1]], If[NumberQ[#4], {#4 10^3}, {}]]]]], AddUnits[#5], AddUnits[#6], AddUnits[#7], AddUnits[#8], AddUnits[#9, "Joules"], AddUnits[#10, "MetricKilotons"] } & @@@ rawdata[[3, 9, 2, 12, 1, 2 ;;]], {_, _Missing, __}];
In[4]:=
Click for copyable input
entities = Association @@ MapIndexed[ "Bolide" <> ToString[First[#2]] -> <| "Date" -> #[[1]], "Position" -> #[[2]], "Velocity" -> #[[3]], "VelocityX" -> #[[4]], "VelocityY" -> #[[5]], "VelocityZ" -> #[[6]], "TotalRadiatedEnergy" -> #[[7]], "CalculatedTotalImpactEnergy" -> #[[8]], "Label" -> "bolide on " <> DateString[#[[1]]] <> " GMT" |> &, bolidedata];
In[5]:=
Click for copyable input
properties = <| "Date" -> <|"Label" -> "date"|>, "Position" -> <|"Label" -> "position"|>, "Velocity" -> <|"Label" -> "velocity"|>, "VelocityX" -> <|"Label" -> "velocity x\[Hyphen]component"|>, "VelocityY" -> <|"Label" -> "velocity y\[Hyphen]component"|>, "VelocityZ" -> <|"Label" -> "velocity z\[Hyphen]component"|>, "TotalRadiatedEnergy" -> <|"Label" -> "total radiated energy"|>, "CalculatedTotalImpactEnergy" -> <|"Label" -> "calculated total impact energy"|> |>;
In[6]:=
Click for copyable input
store = EntityStore["Bolide" -> <| "Label" -> "bolide", "LabelPlural" -> "bolides", "Entities" -> entities, "Properties" -> properties |>]
Out[6]=

Registre o banco de dados para esta sessão.

In[7]:=
Click for copyable input
PrependTo[$EntityStores, store];

Crie uma "EntityAssociation" de posições e energias de bólidos.

In[8]:=
Click for copyable input
ea = EntityValue["Bolide", {"Position", "TotalRadiatedEnergy"}, "EntityAssociation"];

Faça um gráfico geográfico de visibilidades de bólidos com base em suas alturas e posições no céu.

In[9]:=
Click for copyable input
GeoGraphics[{GeoVisibleRegion[#] & @@@ Values[ea]}]
Out[9]=

Extraia energias de bólidos em QuantityArray.

In[10]:=
Click for copyable input
energies = QuantityArray[Values[ea][[All, -1]]]
Out[10]=

Visualize energias de bólidos usando um histograma.

In[11]:=
Click for copyable input
Histogram[energies, "Log", AxesLabel -> {"energy (J)", "count"}]
Out[11]=

Aplique uma função de escala para dar uma imagem qualitativa do brilho da bola de fogo.

mostre o input completo da Wolfram Language
In[12]:=
Click for copyable input
scale[e_] := Quantity[1.*10^4 Sqrt[e/Max[energies]], "Kilometers"]
In[13]:=
Click for copyable input
GeoGraphics[{Red, GeoDisk[#1, scale[#2]] & @@@ Values[ea]}]
Out[13]=

Exemplos Relacionados

en es ja ko ru zh