Wolfram Language

Umfassenderer Zugang zur Knowledgebase

Pokémon-Power

Die Wolfram Knowledgebase enthält sowohl Informationen über Ikonen der Popkultur als auch wissenschaftliches Wissen. In diesem Beispiel untersuchen wir unterschiedliche Charakteristika (Angrifs- und Verteidigungspunkte, Gewicht, Farbe) von Pokémon, wir stellen diese gegenüber und visualisieren sie mit dem eingebauten Entitäten-Framework.

Plotten Sie die Verteilungen von Angriffs- und Verteidigungspunkten aller Pokémon.

In[1]:=
Click for copyable input
PairedHistogram[EntityValue["Pokemon", "Attack"], EntityValue["Pokemon", "Defense"], ChartLabels -> {"attack", "defense"}, ChartStyle -> {{LightOrange, LightBlue}, None}]
Out[1]=

Erstellen Sie ein Dataset der Angriffs- vs. Verteidigungspunkte der Generation VI-Pokémon.

In[2]:=
Click for copyable input
stat = EntityValue[Entity[ "Pokemon", { "Generation" -> Entity[ "PokemonGeneration", "GenerationVI"]}], {"Attack", "Defense"}, "Dataset"];
In[3]:=
Click for copyable input
ListPlot[stat, PlotStyle -> Directive[Opacity[0.5], Orange, PointSize[Medium]], AxesLabel -> Automatic, LabelingFunction -> None]
Out[3]=

Vergleichen und plotten Sie das Durchschnittsgewicht der Pokémon im Laufe der unterschiedlichen Generationen.

In[4]:=
Click for copyable input
wg = Normal[ GroupBy[Rule @@@ EntityValue["Pokemon", {"Generation", "Weight"}], First -> Last, Mean]]
Out[4]=
In[5]:=
Click for copyable input
BarChart3D[wg[[All, 2]], ChartLegends -> wg[[All, 1]], ChartStyle -> 24]
Out[5]=

Verwenden Sie eine implizit definierte Entitätsklasse, um die drei schwersten Pokémon zu eruieren.

In[6]:=
Click for copyable input
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]
Out[6]=
In[7]:=
Click for copyable input
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]; EntityValue[%, "Generation"]
Out[7]=

Ermitteln Sie die gelben Pokémon der Gewichtsklasse 50 bis 100 kg.

In[8]:=
Click for copyable input
yellowMidweights = EntityList[ Entity["Pokemon", {"PokedexColor" -> "Yellow", "Weight" -> Between[{ Quantity[50, "Kilograms"], Quantity[100, "Kilograms"]}]}]]
Out[8]=

Erstellen Sie eine Collage dieser Pokémon-Charaktere, wobei ihre Darstellungsgröße ihrem jeweiligen Gewicht entspricht.

In[9]:=
Click for copyable input
ImageCollage[ Rule @@@ EntityValue[yellowMidweights, {"Weight", "Image"}], Background -> White]
Out[9]=

Vergleichen Sie die Farben der Pokémon des Originals (Generation I) und der jüngsten (Generation VI) Gruppen.

Den kompletten Wolfram Language-Input zeigen
In[10]:=
Click for copyable input
{color1, color6} = Sort[Tally[EntityValue[EntityList[ Entity["Pokemon", {"Generation" -> Entity["PokemonGeneration", #]}]], "PokedexColor"]]] & /@ {"GenerationI", "GenerationVI"};
In[11]:=
Click for copyable input
PieChart3D[{color1[[All, 2]], color6[[All, 2]]}, PlotLabel -> "Gen. I (outer) vs. Gen. VI (inner)", ChartElementFunction -> "ProfileSector3D", SectorOrigin -> {Automatic, 1}, ChartStyle -> (color1[[All, 1]] /. co_Entity :> Symbol[co[[2]]]), ChartLegends -> color1[[All, 1]]]
Out[11]=

Verwandte Beispiele

en es ja ko pt-br ru zh