Wolfram Language

Acceso enriquecido a la base de conocimiento

Potencia de un Pokémon

Wolfram Knowledgebase contiene información acerca de íconos de la cultura popular, así como conocimiento científico. Aquí, varias características físicas (puntos de ataque y defensa, peso, color) de la colección de Pokémon son explorados, contrastados y visualizados usando un marco de entidades incorporado.

Represente gráficamente las distribuciones de los puntos de ataque y defensa de todos los Pokémon.

In[1]:=
Click for copyable input
PairedHistogram[EntityValue["Pokemon", "Attack"], EntityValue["Pokemon", "Defense"], ChartLabels -> {"attack", "defense"}, ChartStyle -> {{LightOrange, LightBlue}, None}]
Out[1]=

Cree un Dataset de puntos de ataque y defensa para la generación VI de Pokémon y grafíquelos uno contra otro.

In[2]:=
Click for copyable input
stat = EntityValue[Entity[ "Pokemon", { "Generation" -> Entity[ "PokemonGeneration", "GenerationVI"]}], {"Attack", "Defense"}, "Dataset"];
In[3]:=
Click for copyable input
ListPlot[stat, PlotStyle -> Directive[Opacity[0.5], Orange, PointSize[Medium]], AxesLabel -> Automatic, LabelingFunction -> None]
Out[3]=

Compare y grafique los pesos promedio de un Pokémon de distintas generaciones.

In[4]:=
Click for copyable input
wg = Normal[ GroupBy[Rule @@@ EntityValue["Pokemon", {"Generation", "Weight"}], First -> Last, Mean]]
Out[4]=
In[5]:=
Click for copyable input
BarChart3D[wg[[All, 2]], ChartLegends -> wg[[All, 1]], ChartStyle -> 24]
Out[5]=

Use una clase de entidades implícitamente definidas para encontrar los tres Pokémon más pesados.

In[6]:=
Click for copyable input
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]
Out[6]=
In[7]:=
Click for copyable input
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]; EntityValue[%, "Generation"]
Out[7]=

Use una clase de entidades implícitamente definida para encontrar el Pokémon color amarillo que pesa entre 50 y 100 kg.

In[8]:=
Click for copyable input
yellowMidweights = EntityList[ Entity["Pokemon", {"PokedexColor" -> "Yellow", "Weight" -> Between[{ Quantity[50, "Kilograms"], Quantity[100, "Kilograms"]}]}]]
Out[8]=

Cree un collage de estos personajes de Pokémon con tamaños basados en sus pesos.

In[9]:=
Click for copyable input
ImageCollage[ Rule @@@ EntityValue[yellowMidweights, {"Weight", "Image"}], Background -> White]
Out[9]=

Compare los colores de Pokémon en el grupo original (Generación I) y en el grupo más reciente (Generación VI).

muestre la entrada completa de Wolfram Language
In[10]:=
Click for copyable input
{color1, color6} = Sort[Tally[EntityValue[EntityList[ Entity["Pokemon", { "Generation" -> Entity["PokemonGeneration", {1, 2}]}]], "PokedexColor"]]] & /@ {"GenerationI", "GenerationVI"};
In[11]:=
Click for copyable input
PieChart3D[{color1[[All, 2]], color6[[All, 2]]}, PlotLabel -> "Gen. I (outer) vs. Gen. VI (inner)", ChartElementFunction -> "ProfileSector3D", SectorOrigin -> {Automatic, 1}, ChartStyle -> (color1[[All, 1]] /. co_Entity :> Symbol[co[[2]]]), ChartLegends -> color1[[All, 1]]]
Out[11]=

Ejemplos relacionados

de en ja ko pt-br ru zh