Wolfram Language

Umfassenderer Zugang zur Knowledgebase

Yoga für Körper und Geist

Die Wolfram Knowledgebase enthält einen kuratierten Datensatz zu Yoga-Positionen. Damit können die Beziehung zwischen Positionen, ihre Schwierigkeitslevels, die beanspruchten Muskeln, ihre Dauer und viele andere Charakteristika in einfacher, präziser und komplett programmatischer Weise untersucht werden.

Ermitteln und visualisieren Sie die Beziehungen der Yoga-Übungen baiserend auf den "PreparatoryPoses"-Beziehungen. Ausgangspunkt ist der Skorpion.

In[1]:=
Click for copyable input
poseGraph = NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &, Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name", VertexLabelStyle -> LightGray]
Out[1]=

Stellen Sie unterschiedliche Positionen schematisch dar.

In[2]:=
Click for copyable input
With[{v = Take[VertexList[poseGraph], 5]}, schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}] ] // Column
Out[2]=

Erstellen Sie eine Graphik von Positionen, die nach "Gemeinsamkeiten" gruppiert sind.

In[3]:=
Click for copyable input
CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e, VertexLabels -> Placed["Name", Tooltip]]
Out[3]=

Zählen Sie die Anzahl der Muskeln, die in der Ashtanga-Positionenfolge angespannt werden und stellen Sie diese der Anzahl beanspruchter Muskeln in einer Graphik gegenüber.

Den kompletten Wolfram Language-Input zeigen
In[4]:=
Click for copyable input
mus = Normal[ EntityValue[ Cases[Entity["YogaSequence", "AshtangaPrimarySeries"][ "PrimaryPoseSequence"] /. Entity["YogaSequence", s_] :> Entity["YogaSequence", s]["PrimaryPoseSequence"], _Entity, Infinity], "PrimaryContractedMuscles", "EntityAssociation"]] /. Rule[l_, r_] :> l -> Length[r];
In[5]:=
Click for copyable input
ListLinePlot[mus[[All, -1]], Filling -> Axis, AspectRatio -> .4, AxesLabel -> {"pose position", "contracted muscles count"}]
Out[5]=

Ermitteln Sie die Muskeln, die in der Positionenfolge des Sonnengrußes A gedehnt werden und visualisieren Sie den am häufigsten gedehnten Muskel.

In[6]:=
Click for copyable input
muscles = (SortBy[ Tally[DeleteMissing[ Flatten[EntityValue[ Cases[Entity["YogaSequence", "SunSalutationA"][ "PrimaryPoseSequence"], _Entity, Infinity], "StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &
Out[6]=

Visualisieren Sie den am häufigsten gedehnten Muskel.

In[7]:=
Click for copyable input
EntityValue[muscles[[1, 1]], "RegionalLocationImage"]
Out[7]=

Ermitteln und visualisieren Sie mittels einer implizit definierten Entitätsklasse mittelschwere Anfänger-Yoga-Übungen zur Dehnung der Beine und Stärkung der Körpermitte.

In[8]:=
Click for copyable input
EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]
Out[8]=

Stellen Sie diese Positionen als eine Entitätsassoziation schematisch dar.

In[9]:=
Click for copyable input
EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]; EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]
Out[9]=

Finden Sie Yoga-Übungen für Fortgeschrittene, die die Hüftmuskulatur und Oberschenkelmuskeln stärken.

In[10]:=
Click for copyable input
EntityValue[ Entity["YogaPose", {"ExperienceLevel" -> "Advanced", "PrimaryContractedMuscles" -> Entity["AnatomicalStructure", "Iliopsoas"], "StretchedMuscles" -> Entity["AnatomicalStructure", "SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]
Out[10]=

Finden Sie Yoga-Übungsabläufe mit einer Dauer zwischen 30 und 60 Minuten.

In[11]:=
Click for copyable input
EntityList@ Entity["YogaSequence", {"EstimatedDuration" -> Quantity[ Interval[{30, 60}], "Minutes"]}]
Out[11]=

Verwandte Beispiele

en es ja ko pt-br ru zh