Wolfram言語

Knowledgebaseへの幅広いアクセス

健康と知識のためのヨガ

Wolfram Knowledgebaseには,ヨガのポーズについてのデータを要約した,精選データ集合が含まれている.このため,ポーズ,難易度,使われる筋肉,持続時間,その他の多くの特徴を,簡単,強力,かつ詳細に,しかも完全にプログラム可能な方法で調べ学ぶことができるようになっている.

サソリのポーズから始め,"PreparatoryPoses"の関係に基づいたヨガのポーズの関係を形にして可視化する.

In[1]:=
Click for copyable input
poseGraph = NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &, Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name", VertexLabelStyle -> LightGray]
Out[1]=

さまざまなポーズの簡単な画像を表示する.

In[2]:=
Click for copyable input
With[{v = Take[VertexList[poseGraph], 5]}, schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}] ] // Column
Out[2]=

インターリンケージを共有する「コミュニティ」ごとにポーズをグループ化してプロットする.

In[3]:=
Click for copyable input
CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e, VertexLabels -> Placed["Name", Tooltip]]
Out[3]=

アシュタンヨガの基本シーケンスにおける一連のポーズで収縮する筋肉を数え,使用される筋肉数とともにプロットする.

完全なWolfram言語入力を表示する
In[4]:=
Click for copyable input
mus = Normal[ EntityValue[ Cases[Entity["YogaSequence", "AshtangaPrimarySeries"][ "PrimaryPoseSequence"] /. Entity["YogaSequence", s_] :> Entity["YogaSequence", s]["PrimaryPoseSequence"], _Entity, Infinity], "PrimaryContractedMuscles", "EntityAssociation"]] /. Rule[l_, r_] :> l -> Length[r];
In[5]:=
Click for copyable input
ListLinePlot[mus[[All, -1]], Filling -> Axis, AspectRatio -> .4, AxesLabel -> {"pose position", "contracted muscles count"}]
Out[5]=

太陽礼拝Aの一連のポーズで伸ばされる筋肉を求め,最も品番に伸ばされる筋肉を可視化する.

In[6]:=
Click for copyable input
muscles = (SortBy[ Tally[DeleteMissing[ Flatten[EntityValue[ Cases[Entity["YogaSequence", "SunSalutationA"][ "PrimaryPoseSequence"], _Entity, Infinity], "StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &
Out[6]=

最も頻繁に伸ばされる筋肉を可視化する.

In[7]:=
Click for copyable input
EntityValue[muscles[[1, 1]], "RegionalLocationImage"]
Out[7]=

隠的に定義された実体クラスを使って,脚の筋肉を伸ばし体幹(コア)の筋肉を鍛える,初心者用の中等度強度のヨガポーズを求め,可視化する.

In[8]:=
Click for copyable input
EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]
Out[8]=

これらのポーズの簡単な画像を実体の連想として見る.

In[9]:=
Click for copyable input
EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]; EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]
Out[9]=

腸腰筋を鍛え膝腱を伸ばす,上級者用のヨガのポーズを表示する.

In[10]:=
Click for copyable input
EntityValue[ Entity["YogaPose", {"ExperienceLevel" -> "Advanced", "PrimaryContractedMuscles" -> Entity["AnatomicalStructure", "Iliopsoas"], "StretchedMuscles" -> Entity["AnatomicalStructure", "SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]
Out[10]=

持続時間が30分から60分の間になるヨガのシーケンスを求める.

In[11]:=
Click for copyable input
EntityList@ Entity["YogaSequence", {"EstimatedDuration" -> Quantity[ Interval[{30, 60}], "Minutes"]}]
Out[11]=

関連する例

de en es ko pt-br ru zh