Wolfram Language

Acesso mais produtivo à base de conhecimento

Yoga para saúde e conhecimento

A Wolfram Knowledgebase inclui um conjunto de dados selecionados de posições de yoga. Como resultado, as relações entre as posições, seus níveis de dificuldade, os músculos que envolvem, suas durações, e muitas outras características podem ser exploradas e estudadas de maneira programática simples, poderosa e precisa.

Visualize as relações entre posições de yoga com base nas relações de "PreparatoryPoses", começando pela posição escorpião.

In[1]:=
Click for copyable input
poseGraph = NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &, Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name", VertexLabelStyle -> LightGray]
Out[1]=

Mostre imagens esquemáticas de diversas poses.

In[2]:=
Click for copyable input
With[{v = Take[VertexList[poseGraph], 5]}, schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}] ] // Column
Out[2]=

Faça um gráfico de posições agrupadas por "comunidades" que compartilham uma relação.

In[3]:=
Click for copyable input
CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e, VertexLabels -> Placed["Name", Tooltip]]
Out[3]=

Conte o número de músculos contraídos na série de posições em uma sequência primária de Ashtanga yoga e faça um gráfico do número de músculos envolvidos.

mostre o input completo da Wolfram Language
In[4]:=
Click for copyable input
mus = Normal[ EntityValue[ Cases[Entity["YogaSequence", "AshtangaPrimarySeries"][ "PrimaryPoseSequence"] /. Entity["YogaSequence", s_] :> Entity["YogaSequence", s]["PrimaryPoseSequence"], _Entity, Infinity], "PrimaryContractedMuscles", "EntityAssociation"]] /. Rule[l_, r_] :> l -> Length[r];
In[5]:=
Click for copyable input
ListLinePlot[mus[[All, -1]], Filling -> Axis, AspectRatio -> .4, AxesLabel -> {"pose position", "contracted muscles count"}]
Out[5]=

Ache os músculos que são alongados na série Saudação ao Sol A e visualize o músculo que é alongado com mais frequência.

In[6]:=
Click for copyable input
muscles = (SortBy[ Tally[DeleteMissing[ Flatten[EntityValue[ Cases[Entity["YogaSequence", "SunSalutationA"][ "PrimaryPoseSequence"], _Entity, Infinity], "StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &
Out[6]=

Visualize o músculo que é alongado com mais frequência.

In[7]:=
Click for copyable input
EntityValue[muscles[[1, 1]], "RegionalLocationImage"]
Out[7]=

Use uma classe de entidade definida implicitamente para encontrar e visualizar posições de ioga para iniciantes e de média intensidade que alonguem a perna e fortaleçam o abdomem.

In[8]:=
Click for copyable input
EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]
Out[8]=

Veja imagens esquemáticas dessas posições como uma associação de entidades.

In[9]:=
Click for copyable input
EntityList[ Entity["YogaPose", {"ExperienceLevel" -> "Beginner", "IntensityLevel" -> "Medium", "SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"], "SitesOfImprovedStrength" -> Entity["AnatomicalStructure", "Abdomen"]}]]; EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]
Out[9]=

Mostre as posições avançadas de yoga que fortalecem o músculo iliopsoas e alongam os isquiossurais.

In[10]:=
Click for copyable input
EntityValue[ Entity["YogaPose", {"ExperienceLevel" -> "Advanced", "PrimaryContractedMuscles" -> Entity["AnatomicalStructure", "Iliopsoas"], "StretchedMuscles" -> Entity["AnatomicalStructure", "SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]
Out[10]=

Encontre sequências de ioga com durações entre 30 e 60 minutos.

In[11]:=
Click for copyable input
EntityList@ Entity["YogaSequence", {"EstimatedDuration" -> Quantity[ Interval[{30, 60}], "Minutes"]}]
Out[11]=

Exemplos Relacionados

de en es ja ko ru zh