Wolfram Language

Traitement des séries temporelles

Approximez al dérivée d'un signal

Utlisez MovingMap pour approximer la dérivée d'un signal provenant de la série temporelle continue irrégulièrement échantillonnée.

In[1]:=
Click for copyable input
ts = TimeSeries[ Table[{t, EllipticTheta[1, t, 0.3]}, {t, Join[{0.}, RandomReal[{0, 2 Pi}, 254], {2. Pi}]}]]
Out[1]=
In[2]:=
Click for copyable input
RegularlySampledQ[ts]
Out[2]=
In[3]:=
Click for copyable input
ListPlot[ts, PlotTheme -> "Detailed"]
Out[3]=

Utilisez les valeurs et les temps au niveau des limites de chaque fenêtre coulissante pour calculer les quotients de différence.

In[4]:=
Click for copyable input
quotient[values_, times_] := First[Differences[values]/Differences[times]]
In[5]:=
Click for copyable input
mm = MovingMap[quotient[#BoundaryValues, #BoundaryTimes] &, ts, {.01, Right}]
Out[5]=

Comparez avec la dérivée théorique.

In[6]:=
Click for copyable input
prime = D[EllipticTheta[1, t, 0.3], t]
Out[6]=
In[7]:=
Click for copyable input
Show[Plot[prime, {t, 0, 2 \[Pi]}, PlotStyle -> Thick, PlotTheme -> "Detailed", PlotLegends -> None], ListPlot[mm, PlotStyle -> Red]]
Out[7]=

Utilisez MovingMap avec Line à la place de la fonction de quotient pour créer un tracé de lignes sécantes approximatives de la série temporelle originale.

In[8]:=
Click for copyable input
line[yvals_, xvals_] := Line[Transpose[{xvals, yvals}]];
In[9]:=
Click for copyable input
lines = MovingMap[ line[#BoundaryValues, #BoundaryTimes] &, ts, {1.3, Right, {0, 2. \[Pi], .1}}];
In[10]:=
Click for copyable input
Graphics[{Black, lines["Values"]}]
Out[10]=

Exemples connexes

de en es ja ko pt-br ru zh