Wolfram Language

Unités et dates

Estimez l'accélération de la pesanteur

L'accélération de la pesanteur peut être obtenue en mesurant la durée d'un pendule T et sa longueur, en utilisant . L'incertitude de la moyenne des cinq mesures répétées de la période est modélisée avec une BatesDistribution.

In[1]:=
Click for copyable input
\[Mu]T = Quantity[2, "Seconds"]; \[CapitalDelta]T = Quantity[0.01, "Seconds"]; period\[ScriptCapitalD] = BatesDistribution[ 5, {\[Mu]T - \[CapitalDelta]T/2, \[Mu]T + \[CapitalDelta]T/2}]
Out[1]=

La longueur du pendule a été mesurée en utilisant une règle avec une résolution de 1 mm, de sorte que son incertitude est modélisée avec une UniformDistribution.

In[2]:=
Click for copyable input
\[Mu]len = Quantity[1, "Meters"]; \[CapitalDelta]len = UnitConvert[Quantity[1, "mm"], "Meters"]; len\[ScriptCapitalD] = UniformDistribution[{\[Mu]len - \[CapitalDelta]len/ 2., \[Mu]len + \[CapitalDelta]len/2.}]
Out[2]=

L'incertitude sur la mesure de l'accélération de la pesanteur.

In[3]:=
Click for copyable input
g\[ScriptCapitalD] = TransformedDistribution[ (2 \[Pi])^2 len/T^2, {len \[Distributed] len\[ScriptCapitalD], T \[Distributed] period\[ScriptCapitalD]}]
Out[3]=

Comparez à l'approximation linéaire.

In[4]:=
Click for copyable input
lin[e_, {x_, x0_}, {y_, y0_}] := Block[{f = Function @@ {{x, y}, e}}, f[x0, y0] + \!\(\*SuperscriptBox[\(f\), TagBox[ RowBox[{"(", RowBox[{"1", ",", "0"}], ")"}], Derivative], MultilineFunction->None]\)[x0, y0] (x - x0) + \!\(\*SuperscriptBox[\(f\), TagBox[ RowBox[{"(", RowBox[{"0", ",", "1"}], ")"}], Derivative], MultilineFunction->None]\)[x0, y0] (y - y0)]
In[5]:=
Click for copyable input
lin\[ScriptCapitalD][\[ScriptCapitalD]_] := NormalDistribution[Mean[\[ScriptCapitalD]], StandardDeviation[\[ScriptCapitalD]]]
In[6]:=
Click for copyable input
gApprox\[ScriptCapitalD] = TransformedDistribution[ lin[(2 Pi)^2 len/ T^2, {len, \[Mu]len}, {T, \[Mu]T}], {len \[Distributed] lin\[ScriptCapitalD][len\[ScriptCapitalD]], T \[Distributed] lin\[ScriptCapitalD][period\[ScriptCapitalD]]}]
Out[6]=

Calculez l'accélération moyenne en utilisant l'exacte et les distributions linéarisées.

In[7]:=
Click for copyable input
{\[Mu]g, \[Mu]gApprox} = {NExpectation[g, g \[Distributed] g\[ScriptCapitalD]], NExpectation[g, g \[Distributed] gApprox\[ScriptCapitalD]]}
Out[7]=

Calculez les échelles d'incertitude.

In[8]:=
Click for copyable input
{\[Sigma]g, \[Sigma]gApprox} = {Sqrt[ NExpectation[(g - \[Mu]g)^2, g \[Distributed] g\[ScriptCapitalD]]], StandardDeviation[gApprox\[ScriptCapitalD]]}
Out[8]=

Trouvez l'estimation d'échantillonnage de l'intervalle de confiance de 90% pour l'accélération mesurée.

In[9]:=
Click for copyable input
confidenceInterval = Quantile[RandomVariate[g\[ScriptCapitalD], 10^6], {0.05, 0.95}]
Out[9]=
In[10]:=
Click for copyable input
NProbability[First[confidenceInterval] < x < Last[confidenceInterval], x \[Distributed] g\[ScriptCapitalD]]
Out[10]=

Exemples connexes

de en es ja ko pt-br ru zh