Analyzing and Rendering Simulation Data 

Visualizing and analyzing the simulation results of hurricane Isabel from the National Center for Atmospheric Research (NCAR).

Hurricane Isabel data produced by the Weather Research and Forecast (WRF) model, courtesy of NCAR, and the US National Science Foundation (NSF).

Import and visualize the elevation data using an appropriate color function.

show complete Wolfram Language inputhide input

In[1]:=

X GetUCARFile[filename_String] := Module[ {url = "http://www.vets.ucar.edu/vg/isabeldata/"}, If[Not@FileExistsQ[filename], URLSave[url <> filename, filename]]; Import[filename, {"GZIP", "Binary", "Real32"}, ByteOrdering -> 1] ]

In[2]:=

X UCARFileToImage3D[data_, opts___Rule] := Image3D[Reverse@Transpose[ Partition[Partition[Clip[data, 2^16 {-1, 1}, {0, 0}], 500], 500], {1, 3, 2}], "Real32", opts];

In[3]:=

X elevation = Transpose@Partition[GetUCARFile["HGTdata.bin.gz"], 500];

In[4]:=

X groundColor = Blend[{{0., RGBColor[0., 0.0675975, 0.467384]}, {0.001, RGBColor[ 0.42313633333333334`, 0.4823743333333333, 0.434165]}, {0.3, RGBColor[0.4680942, 0.4216284, 0.29627780000000004`]}, {0.6, RGBColor[ 0.5066887333333333, 0.3798376666666667, 0.24217553333333333`]}, {0.8, RGBColor[ 0.6809748666666666, 0.5876996666666666, 0.49616886666666665`]}, {1., RGBColor[1., 1., 1.]}}, #] &; ground = ListPlot3D[ Reverse@ArrayResample[GaussianFilter[elevation/200, {12, 4}], 128], PlotStyle -> Texture[ReliefImage[elevation, PlotRange -> All, ColorFunction -> groundColor]], DataRange -> {{0, 500}, {0, 500}, {0, 100}}, BoxRatios -> {1, 1, 0.1}, PlotRange -> All, Mesh -> None, Axes -> False]

Out[4]=

Import the volumetric cloud data at time step and superimpose it on the elevation map. The download may take a while.

In[5]:=

X clouds = ImageAdjust[UCARFileToImage3D[ GetUCARFile["CLOUDf30.bin.gz"], ColorFunction -> "WhiteBlackOpacity"]]; Show[clouds, ground]

Out[5]=

Create a mask for the airspace over land.

In[6]:=

X mask = Image3D[ Table[UnitStep[ elevation - $MachineEpsilon], {ImageDimensions[clouds][[3]]}], "Bit"]

Out[6]=

Measure the cloud (water[kg]/air[kg]) cover over land and over sea.

In[7]:=

X landCloud = ImageMeasurements[clouds, {"Min", "Mean", "Max"}, Masking -> mask]

Out[7]=

In[8]:=

X seaCloud = ImageMeasurements[clouds, {"Min", "Mean", "Max"}, Masking -> ColorNegate[mask]]

Out[8]=

Out[9]//TraditionalForm=

Import wind velocities in x, y, and z direction to determine and display wind magnitude.

show complete Wolfram Language inputhide input

In[9]:=

X windRescale = 0.0125;

In[10]:=

X xWind = UCARFileToImage3D[windRescale * GetUCARFile["Uf30.bin.gz"]]; yWind = UCARFileToImage3D[windRescale * GetUCARFile["Vf30.bin.gz"]]; zWind = UCARFileToImage3D[windRescale * GetUCARFile["Wf30.bin.gz"]];

In[11]:=

X windColors = Blend[ {{0, Opacity[0, RGBColor[0.178927, 0.305394, 0.933501]]}, {0.2, Opacity[0.008, RGBColor[ 0.6636740000000001, 0.73718644, 0.9671124799999999]]}, {0.4, Opacity[0.032, RGBColor[ 0.9868536, 0.98883164, 0.8675333999999999]]}, {0.6, Opacity[0.072, RGBColor[ 0.93733804, 0.7892732399999997, 0.2684389199999999]]}, {0.8, Opacity[0.128, RGBColor[0.817319, 0.134127, 0.164218]]}, {1, Opacity[0.2, RGBColor[0.817319, 0.134127, 0.164218]]}}, #] &; wind = Image3D[ImageApply[ Norm, Image3D[ColorCombine[{xWind, yWind, zWind}]]], ColorFunction -> windColors]; Show[wind, ground, ViewPoint -> {0, 0, 2}, Boxed -> False]

Out[11]=

Measure wind magnitude over land and over sea.

In[12]:=

X landWind = UnitConvert[ Quantity[ImageMeasurements[wind, {"Min", "Mean", "Max"}, Masking -> mask]/windRescale, "m/s"], "km/h"]

Out[12]=

In[13]:=

X seaWind = UnitConvert[ Quantity[ImageMeasurements[wind, {"Min", "Mean", "Max"}, Masking -> ColorNegate@mask]/windRescale, "m/s"], "km/h"]

Out[13]=

Out[14]//TraditionalForm=