New in Wolfram Mathematica 7: Discrete Calculus  previous | next 
Generate Symbolic Z Transforms
Generate symbolic univariate and multivariate Z transforms.
In[1]:=

Click for copyable input
problems = {HoldForm[ZTransform[UnitStep[n], n, z]], 

   HoldForm[ZTransform[E^(-\[Alpha] n), n, z]],

   HoldForm[ZTransform[Sin[\[Alpha] n], n, z]], 

   HoldForm[ZTransform[n^3 + 3 n + 1, n, z]], 

   HoldForm[ZTransform[n^k, n, z]],

   HoldForm[ZTransform[n a^n/((n + 1) (n + 2)), n, z]],

   HoldForm[ZTransform[ChebyshevU[n, x], n, z]], 

   HoldForm[ZTransform[LaguerreL[n, x], n, z]], 

   HoldForm[ZTransform[a^n Cos[Pi n], n, z]], 

   HoldForm[ZTransform[n^2 2^(-n), n, z]], 

   HoldForm[ZTransform[Sum[f[m], {m, 0, n}], n, z]], 

   HoldForm[ZTransform[f[n + 1], n, z]], 

   HoldForm[ZTransform[(m + 1) (n - m), {n, m}, {u, v}]], 

   HoldForm[ZTransform[a^n  m^3, {n, m}, {u, v}]]};
In[2]:=

Click for copyable input
FormulaGallery[forms_List] := 

 Module[{vals = ParallelMap[ReleaseHold, forms]}, 

  Text@TraditionalForm@

    Grid[Table[{forms[[i]], "==", vals[[i]]}, {i, Length[forms]}], 

     Dividers -> {{True, False, False, True}, All}, 

     Alignment -> {{Right, Center, Left}, Baseline}, 

     Background -> LightYellow, Spacings -> {{4, {}, 4}, 1}]]
In[3]:=

Click for copyable input
FormulaGallery[problems]
Out[3]=