New in Wolfram Mathematica 7: Discrete Calculus  previous | next 
Solve New Classes of Functional Equations
Solve new classes of functional equations, including arithmetic geometric, linear fractional and geometric power.
In[1]:=

Click for copyable input
problems = {{"Arithmetic", 

    HoldForm[

     RSolve[y[n + 1/3] == 2 y[n + 1/6] + n^2, y[n], 

      n]]}, {"Geometric", 

    HoldForm[

     RSolve[y[n] == -2 y[n/2] + y[n/4] + n, y[n], 

      n]]}, {"Arithmetic geometric", 

    HoldForm[

     RSolve[y[n] == 2^(n/2) y[n/2 + 1] + 9 2^n (n/2 + 1), y[n], 

      n]]}, {"Linear fractional", 

    HoldForm[RSolve[y[(2 n - 1)/(-n + 2)] == 3 y[n] + 5, y[n], n]]},

   {"Geometric power", 

    HoldForm[RSolve[ y[n] == Sqrt[n] y[Sqrt[n]] + n, y[n], n ]]},

   {"General", 

    HoldForm[RSolve[y[Exp[n]] == -2 y[Exp[n/2]] + n, y[n], n]]}};
In[2]:=

Click for copyable input
FormulaGallery[forms_List] := 

 Module[{vals = ParallelMap[ReleaseHold, forms]}, 

  Text@TraditionalForm@

    Grid[Table[{forms[[i]], "==", vals[[i]]}, {i, Length[forms]}], 

     Dividers -> {{True, False, False, True}, All}, 

     Alignment -> {{Right, Center, Left}, Baseline}, 

     Background -> LightYellow, Spacings -> {Automatic, 2}]]
In[3]:=

Click for copyable input
FormulaGallery[Last /@ problems]
Out[3]=