Explore the Earth's Curvature 

Show how the Earth's curvature affects paths on its surface.

Define a path that starts at the Eiffel Tower and travels 100 km along geodesic lines in each of the four compass directions in turn.

In[1]:=

X start = Entity["Building", "TourEiffel"][ EntityProperty["Building", "Position"]]; d = Quantity[100, "Kilometers"]; path = {GeoDisplacement[{d, "North"}, "Geodesic"], GeoDisplacement[{d, "East"}, "Geodesic"], GeoDisplacement[{d, "South"}, "Geodesic"], GeoDisplacement[{d, "West"}, "Geodesic"]};

Draw the four path segments and zoom in to verify that they do not close due to the Earth's curvature.

In[2]:=

X GraphicsRow[ Apply[GeoGraphics[{Red, PointSize[Large], Point[start], Darker[Green], Thickness[Large], GeoPath[{start, path}]}, ##1] &, {{}, {GeoCenter -> start, GeoRange -> Quantity[3, "Kilometers"]}}, {1}]]

Out[2]=

Find the distance between the start and finish points.

In[3]:=

X GeoDistance[start, Last[GeoDestination[start, path]]]

Out[3]=

Now follow loxodrome segments (curves of constant rhumb) instead of geodesics.

In[4]:=

X d = Quantity[100, "Kilometers"]; path = {GeoDisplacement[{d, "North"}, "Rhumb"], GeoDisplacement[{d, "East"}, "Rhumb"], GeoDisplacement[{d, "South"}, "Rhumb"], GeoDisplacement[{d, "West"}, "Rhumb"]};

The latitude of the final point coincides with that of the beginning, but not its longitude.

In[5]:=

X GraphicsRow[ Apply[GeoGraphics[{Red, PointSize[Large], Point[start], Darker[Green], Thickness[Large], GeoPath[{start, path}]}, ##1] &, {{}, {GeoCenter -> start, GeoRange -> Quantity[3, "Kilometers"]}}, {1}]]

Out[5]=

Find the distance between the start and finish points.

In[6]:=

X GeoDistance[start, Last[GeoDestination[start, path]]]

Out[6]=