Разработка программного обеспечения

Исследуйте детали множества Мандельброта

Благодаря увеличению скорости вычислений, те вычисления, которые занимали много времени теперь могут быть произведены в режиме реального времени.

Исследуйте детали множества Мандельброта.

Благодаря быстроте вычислений результат допускает интерактивную визуализацию.

Благодаря использованию синтаксиса системы Mathematica достигается высокая скорость внесения изменений.

In[1]:=

Out[1]=

In[2]:=

mandelComp =

Compile[{{c, _Complex}},

Module[{num = 1},

FixedPoint[(num++; #^2 + c) &, 0, 30,

SameTest -> (Re[#]^2 + Im[#]^2 >= 4 &)]; num],

CompilationTarget -> "C",

RuntimeAttributes -> {Listable},

Parallelization -> True];

doPlotDrag[{x_, y_}] := Panel[

DynamicModule[{dragstart = {0, 0}, dragval = {0, 0},

draghold = {x, y}, xrange, yrange, m = -Log[2, 1.5], scale = 1.5},

Column[{

Row[{"Zoom ",

Slider[Dynamic[m, Function[scale = 2.^-#; m = #]], {-1, 50}],

Dynamic[m]}],

EventHandler[

Dynamic[{xshift,

yshift} = (dragstart - dragval + draghold) {1, -1};

{ylo, yhi} = yshift + scale*{-1, 1};

{xlo, xhi} = xshift + scale*{-1, 1};

xrange = {b, xlo, xhi, .01 scale};

yrange = {a, ylo, yhi, .01*scale};

data = Table[a + I b, Evaluate[yrange], Evaluate[xrange]];

ArrayPlot[mandelComp[data], ImageSize -> 300]],

"MouseDown" :> (dragval =

dragstart = scale*MousePosition["GraphicsScaled"]),

"MouseDragged" :> (dragval =

scale*MousePosition["GraphicsScaled"]),

"MouseUp" :> (draghold = draghold + dragstart - dragval;

dragstart = dragval = {0, 0})]}]]

]

doPlotDrag[{0, 1}]

Out[2]=

In[3]:=