Надёжность работы самолёта 

In[1]:=

X {\[ScriptCapitalD]Motor, \[ScriptCapitalD]Fuel, \ \[ScriptCapitalD]Cooling, \[ScriptCapitalD]Propeller} = \ {WeibullDistribution[1.58, 4830], WeibullDistribution[1.44, 5130], WeibullDistribution[1.60, 4190], WeibullDistribution[1.63, 3740]};

In[2]:=

X \[ScriptCapitalR]SingleEngine = ReliabilityDistribution[ motor \[And] fuel \[And] cooling \[And] propeller, {{motor, \[ScriptCapitalD]Motor}, {fuel, \ \[ScriptCapitalD]Fuel}, {cooling, \[ScriptCapitalD]Cooling}, \ {propeller, \[ScriptCapitalD]Propeller}}];

In[3]:=

X \[ScriptCapitalR]Engines = ReliabilityDistribution[(engine1 \[Or] engine2) \[And] (engine3 \[Or] engine4), {{engine1, \[ScriptCapitalR]SingleEngine}, {engine2, \ \[ScriptCapitalR]SingleEngine}, {engine3, \ \[ScriptCapitalR]SingleEngine}, {engine4, \ \[ScriptCapitalR]SingleEngine}}];

In[4]:=

X parameters = {{1.85, 1.57, 2.25, 0.95, 0.73, 1.14, 0.92, 1.65}, {4729.02, 4718.22, 5843.58, 3956, 2672.1, 3977.39, 2895.62, 3994.78}};

In[5]:=

X {\[ScriptCapitalD]Directional, \[ScriptCapitalD]Longitudinal, \ \[ScriptCapitalD]Lateral, \[ScriptCapitalD]Flaps, \ \[ScriptCapitalD]Trim, \[ScriptCapitalD]Hydraulic, \ \[ScriptCapitalD]LandingGear, \[ScriptCapitalD]Steering} = Flatten[Transpose[{MapThread[WeibullDistribution, parameters]}]];

In[6]:=

X \[ScriptCapitalR]ACS = ReliabilityDistribution[ x1 \[And] x2 \[And] x3 \[And] x4 \[And] x5 \[And] x6 \[And] x7 \[And] x8, {{x1, \[ScriptCapitalD]Directional}, {x2, \ \[ScriptCapitalD]Longitudinal}, {x3, \[ScriptCapitalD]Lateral}, {x4, \ \[ScriptCapitalD]Flaps}, {x5, \[ScriptCapitalD]Trim}, {x6, \ \[ScriptCapitalD]Hydraulic}, {x7, \[ScriptCapitalD]LandingGear}, {x8, \ \[ScriptCapitalD]Steering}}];

In[7]:=

X \[ScriptCapitalD]Wing = WeibullDistribution[1.79, 4250];

In[8]:=

X \[ScriptCapitalR]Airplane = ReliabilityDistribution[ enginesystem \[And] wing1 \[And] wing2 \[And] acs, {{enginesystem, \[ScriptCapitalR]Engines}, {wing1, \ \[ScriptCapitalD]Wing}, {wing2, \[ScriptCapitalD]Wing}, {acs, \ \[ScriptCapitalR]ACS}}];

Значимость по Фусселю-Весселю для различных частей двигателя.

In[9]:=

X Plot[Evaluate@ FussellVeselyImportance[\[ScriptCapitalR]SingleEngine, t], {t, 0, 1000}, Filling -> Axis, PlotLegends -> {"Motor", "Fuel", "Cooling", "Propeller"}, ImageSize -> Medium]

Out[9]=

Средняя продолжительность срока службы самолёта.

In[10]:=

X NExpectation[t, t \[Distributed] \[ScriptCapitalR]Airplane]

Out[10]=

Вероятность того, что шестичасовой перелёт произойдёт без поломок.

In[11]:=

X NProbability[t >= 6, t \[Distributed] \[ScriptCapitalR]Airplane]

Out[11]=

Вероятного того, что самолёт, исправно работающий после 300 часов эксплуатации, останется в исправном состоянии в последующие 200 часов эксплуатации.

In[12]:=

X NProbability[t >= 500 \[Conditioned] t >= 300, t \[Distributed] \[ScriptCapitalR]Airplane]

Out[12]=

Функция надёжности.

In[13]:=

X Plot[Evaluate@SurvivalFunction[\[ScriptCapitalR]Airplane, t], {t, 0, 2000}, Filling -> Axis]

Out[13]=

Случайные реализации срока службы самолёта.

In[14]:=

X ListPlot[{RandomVariate[\[ScriptCapitalR]Airplane, 100], {{0, NExpectation[t, t \[Distributed] \[ScriptCapitalR]Airplane]}, {100, NExpectation[t, t \[Distributed] \[ScriptCapitalR]Airplane]}}}, Joined -> {False, True}, Filling -> Axis, AxesOrigin -> {0, 0}]

Out[14]=