Расчёт ПИД регулятора комнатной температуры 

Расчёт ПИД регулятора, поддерживающего комнатную температуру на уровне 22 °C, даже при флуктуациях наружной температуры, моделируемой как возмущение.

Зададим модели.

In[1]:=

X {valve, burner, thermres, room} = {TransferFunctionModel[Unevaluated[{{1/(1 + 4 s)}}], s, SamplingPeriod ->None, SystemsModelLabels -> {{None}, {None}}], TransferFunctionModel[Unevaluated[{{5}}], s, SamplingPeriod ->None, SystemsModelLabels -> {{None}, {None}}], TransferFunctionModel[Unevaluated[{{0.1}}], s, SamplingPeriod ->None, SystemsModelLabels -> {{None}, {None}}], TransferFunctionModel[Unevaluated[{{1/(1 + 8 s)}}], s, SamplingPeriod ->None, SystemsModelLabels -> {{None}, {None}}]};

In[2]:=

X hsys = SystemsModelSeriesConnect[valve, SystemsModelSeriesConnect[burner, thermres]];

In[3]:=

X lsys = SystemsModelSeriesConnect[room, hsys];

Получим регулятор.

In[4]:=

X pid = PIDTune[lsys, {Automatic, "AMIGO"}, "PIDData"];

Передаточная функция возмущение-отклик.

In[5]:=

X doTFM = SystemsModelFeedbackConnect[room, SystemsModelSeriesConnect[pid["Feedback"], hsys]]

Out[5]=

Получим архивные данные температуры наружного воздуха для определенного города.

In[6]:=

X {times, values} = WeatherData["Chicago", "Temperature", {DatePlus[Date[], -1], Date[]}] // Transpose;

Строим непрерывную функцию температуры от времени.

In[7]:=

X timeSec = DateDifference[First[times], #, "Second"][[1]] & /@ times;

In[8]:=

X d = Interpolation[Transpose[{timeSec, values}]];

Находим значение регулируемой комнатной температуры поминутно.

In[9]:=

X temp = OutputResponse[pid["ReferenceOutput"], 22, {t, 0, Last[timeSec]}] + OutputResponse[doTFM, d[t], {t, 0, Last[timeSec]}];

In[10]:=

X temps = Table[temp, {t, 0, Last[timeSec], 60}] // Flatten;

Строим график комнатной и уличной температур воздуха.

In[11]:=

X roomTplot = DateListPlot[temps, {First[times], Last[times]}, PlotStyle -> Red, Joined -> True, PlotLegends -> LineLegend[{"Room temperature"}]];

In[12]:=

X outTplot = DateListPlot[Transpose[{times, values}], Joined -> True, PlotLegends -> LineLegend[{"Outside temperature"}]];

In[13]:=

X Show[roomTplot, outTplot, ImageSize -> Medium, FrameLabel -> {"Hours", "\[Degree]C"}, PlotRange -> {-5, 25}]

Out[13]=