Regularize Divergent Sums and Products

New in Wolfram Mathematica 7: Discrete Calculus

Many divergent sums and products can be given a finite value through regularization. Convergent sums and products produce the ordinary value under regularization.

In[1]:=

problems = {HoldForm[

    Sum[(-1)^k, {k, 0, Infinity}, Regularization -> "Abel"]], 

   HoldForm[Sum[k*k!, {k, 0, Infinity}, Regularization -> "Borel"]], 

   HoldForm[

    Sum[Sin[k], {k, 0, Infinity}, Regularization -> "Cesaro"]], 

   HoldForm[Sum[k, {k, 1, Infinity}, Regularization -> "Dirichlet"]], 

   HoldForm[

    Sum[(-1)^k*(k + 1), {k, 0, Infinity}, Regularization -> "Euler"]],

    HoldForm[

    Product[k^2, {k, 1, Infinity}, Regularization -> "Dirichlet"]]};

In[2]:=

FormulaGallery[forms_List] := 

 Module[{vals = ParallelMap[ReleaseHold, forms]}, 

  Text@TraditionalForm@

    Grid[Table[{forms[[i]], "==", vals[[i]]}, {i, Length[forms]}], 

     Dividers -> {{True, False, False, True}, All}, 

     Alignment -> {{Right, Center, Left}, Baseline}, 

     Background -> LightYellow, Spacings -> {Automatic, 2}]]

In[3]:=

FormulaGallery[problems]

Out[3]=