‹›图像和信号处理交互式图像测量
DynamicImage 帮助构建自定义界面,使用户可以交互式地对图像中的物体进行测量.
现在考虑如何测量细胞半径
.
使用 Alt+click 定位黄色测量圆圈的中心.
移动滑块,改变圆的半径
.
显示完整的 Wolfram 语言输入
measurementCircle[Dynamic[center_], Dynamic[r_]] := {Yellow, Thick,
Dynamic@Circle[center, r],
Dynamic@Text[
Style[StringJoin[ToString@Round@r, "px"], FontSize -> 18],
Scaled@{0.1, 0.9}, Background -> RGBColor[0, 0, 0, 0.5]]};
DynamicModule[
{center = ImageDimensions[img1]/2, r},
Manipulate[
EventHandler[
DynamicImage[
img1,
Epilog -> measurementCircle[Dynamic[center], Dynamic[r]]
],
{"MouseDown" :>
If[CurrentValue["OptionKey"],
center = MousePosition["Graphics"]]},
PassEventsDown -> Dynamic[Not[CurrentValue["OptionKey"]]]
],
{{r, 32}, 8, 800},
FrameMargins -> 0
]
]
通过手动跟踪测量 DNA 链的长度.
使用 Alt+click 放置线段的顶点. Alt+Shift+click 可以删除最后一个点.
显示完整的 Wolfram 语言输入
measurementLine[Dynamic[pts_], Dynamic[length_]] := {Yellow, Thick,
Dynamic@Line[pts],
Dynamic@Text[
Style[StringJoin[ToString@Round@length, "px"], FontSize -> 18],
Scaled@{0.1, 0.9}, Background -> RGBColor[0, 0, 0, 0.5]]}
DynamicModule[
{pts = {}, length = 0},
Panel@EventHandler[
DynamicImage[
img2,
Epilog -> measurementLine[Dynamic[pts], Dynamic[length]]
],
{"MouseDown" :>
If[CurrentValue["OptionKey"],
If[CurrentValue["ShiftKey"], pts = Most[pts],
AppendTo[pts, MousePosition["Graphics"]]];
length =
Total@Apply[EuclideanDistance, Partition[pts, 2, 1], {1}]]},
PassEventsDown -> Dynamic[Not[CurrentValue["OptionKey"]]]
]
]