Medição interativa de imagens : Novos Recursos do Wolfram Language 11

Medição interativa de imagens

DynamicImage facilita a construção de interfaces personalizadas para medir de forma interativa objetos em imagens.

Considere a medição do raio de uma célula.

In[1]:=

Use Alt+click para posicionar o centro de um círculo de medição amarelo. Mova o controle deslizante para alterar o raio r do círculo.

mostre o input completo da Wolfram Language

In[2]:=

measurementCircle[Dynamic[center_], Dynamic[r_]] := {Yellow, Thick, 
   Dynamic@Circle[center, r], 
   Dynamic@Text[
     Style[StringJoin[ToString@Round@r, "px"], FontSize -> 18], 
     Scaled@{0.1, 0.9}, Background -> RGBColor[0, 0, 0, 0.5]]};
DynamicModule[
 {center = ImageDimensions[img1]/2, r},
 Manipulate[
  EventHandler[
   DynamicImage[
    img1,
    Epilog -> measurementCircle[Dynamic[center], Dynamic[r]]
    ],
   {"MouseDown" :> 
     If[CurrentValue["OptionKey"], 
      center = MousePosition["Graphics"]]},
   PassEventsDown -> Dynamic[Not[CurrentValue["OptionKey"]]]
   ],
  {{r, 32}, 8, 800},
  FrameMargins -> 0
  ]
 ]

Reproduzir

Parar

Meça o comprimento de uma cadeia de DNA traçando-o manualmente.

In[3]:=

Use Alt+click para colocar os vértices de uma linha. Alt+Shift+click deleta o último vértice.

mostre o input completo da Wolfram Language

In[4]:=

measurementLine[Dynamic[pts_], Dynamic[length_]] := {Yellow, Thick, 
  Dynamic@Line[pts], 
  Dynamic@Text[
    Style[StringJoin[ToString@Round@length, "px"], FontSize -> 18], 
    Scaled@{0.1, 0.9}, Background -> RGBColor[0, 0, 0, 0.5]]}
DynamicModule[
 {pts = {}, length = 0},
 Panel@EventHandler[
   DynamicImage[
    img2,
    Epilog -> measurementLine[Dynamic[pts], Dynamic[length]]
    ],
   {"MouseDown" :> 
     If[CurrentValue["OptionKey"], 
      If[CurrentValue["ShiftKey"], pts = Most[pts], 
       AppendTo[pts, MousePosition["Graphics"]]]; 
      length = 
       Total@Apply[EuclideanDistance, Partition[pts, 2, 1], {1}]]},
   PassEventsDown -> Dynamic[Not[CurrentValue["OptionKey"]]]
   ]
 ]