Utilisez des séries temporelles pour générer de l'audio
Contrôler la fréquence de l'onde sinusoïdale avec une TimeSeries échantillonnée régulièrement
In[1]:=
n = 50;
frequencies = RandomReal[{100, 300}, n];
reg = TimeSeries[frequencies, {0, Automatic, .3}];In[2]:=
AudioGenerator[{"Sin", reg}]Out[2]=
Contrôler la fréquence de l'onde sinusoïdale avec une TimeSeries échantillonnée irrégulièrement.
In[3]:=
times = Accumulate[RandomReal[{0.1, .5}, n]];
irreg = TimeSeries[frequencies, {times}];In[4]:=
AudioGenerator[{"Sin", irreg}]Out[4]=
Générez un bruit blanc avec WhiteNoiseProcess.
In[5]:=
sample = RandomFunction[WhiteNoiseProcess[1/3], {88200}]Out[5]=
Changez l'échelle de l'échantillon à la longueur de 2 secondes et générez l' audio.
In[6]:=
AudioNormalize@
AudioGenerator[TimeSeriesRescale[sample, {0, 2, 1/44100}]]Out[6]=
In[7]:=
AudioNormalize@
AudioGenerator[TimeSeriesRescale[sample, {0, 2, 1/44100}]];
AudioPlot[%]Out[7]=
Générez un type de bruit différent directement avec FractionalGaussianNoiseProcess.
In[8]:=
AudioNormalize@AudioGenerator[FractionalGaussianNoiseProcess[1/3], 2]Out[8]=
In[9]:=
AudioNormalize@AudioGenerator[FractionalGaussianNoiseProcess[1/3], 2];
AudioPlot[%]Out[9]=
