Wolfram Language

Traitement des séries temporelles

Missions spatiales habitées

MannedSpaceMissionData fournit des informations historiques et actuelles concernant l'exploration spatiale humaine.

In[1]:=
Click for copyable input
missions = MannedSpaceMissionData[];

Vous pouvez créer un EventSeries basé sur la date de lancement des missions avec des valeurs vectorielles stockant l'entité de la mission et la durée de chaque mission.

In[2]:=
Click for copyable input
data = DeleteMissing[ MannedSpaceMissionData[ missions, {"LaunchDate", "Entity", "MissionDuration"}], 1, 2];
In[3]:=
Click for copyable input
es = EventSeries[data[[All, {2, 3}]], {data[[All, 1]]}]
Out[3]=

Le tracé TimelinePlot des horodotages montre la durée presque continue des missions spatiales habitées depuis 1961.

In[4]:=
Click for copyable input
TimelinePlot[es["Dates"]]
Out[4]=

Pour analyser les durées des missions, extrayez la deuxième composante de l'événement de la série originale et convertissez les valeurs en heures.

In[5]:=
Click for copyable input
durations = UnitConvert[es["PathComponent", 2], "Hours"]
Out[5]=

Les missions courtes sont les plus courantes.

In[6]:=
Click for copyable input
Histogram[durations, Quantity[{0, 6000, 500}, "Hours"], AxesLabel -> Automatic]
Out[6]=
Afficher l'entrée complète de Wolfram Language
In[7]:=
Click for copyable input
x1 = 250; x2 = 4500; line1 = {{es["FirstDate"], x1}, {es["LastDate"], x1}}; line2 = {{es["FirstDate"], x2}, {es["LastDate"], x2}}; opts = {Joined -> {False, True, True}, Filling -> {1 -> 0}, PlotLabels -> {None, Quantity[x1, "Hours"], UnitConvert[Quantity[N[x2, 4], "Hours"], "Days"]}};
In[8]:=
Click for copyable input
DateListPlot[{durations, line1, line2}, opts]
Out[8]=

Calculez les statistiques descriptives des durées des missions. Notez que la moyenne et la médiane sont très éloignées l'une de l'autre, ce qui indique une distribution à longue queue.

In[9]:=
Click for copyable input
stats = {Min, Max, Mean, Median}; convert := UnitConvert[N[#], MixedUnit[{"Months", "Days", "Hours", "Minutes"}]] &
In[10]:=
Click for copyable input
TableForm[Map[convert[#[durations]] &, stats], TableHeadings -> {stats}]
Out[10]//TableForm=

Le temps total pendant lequel il y a eu un être humain dans l'espace.

In[11]:=
Click for copyable input
UnitConvert[Total[durations], MixedUnit[{"Years", "Months", "Days", "Hours", "Minutes", "Seconds"}]]
Out[11]=

Exemples connexes

de en es ja ko pt-br ru zh