Перевод на календарь майя

Идентифицируйте эпоху (или дату начала) для календаря длинного счёта майя в виде даты по юлианскому календарю.

In[1]:=

epoch = JulianDate["Modified", DateObject[{-3114, 8, 11}, TimeZone -> 0]];

Создайте функцию для перевода из даты календаря длинного счёта майя в дату по юлианскому календарю.

In[2]:=

JulianFromMayanLongCount[{baktun_, katun_, tun_, uinal_, kin_}] := epoch + 144000*baktun + 7200*katun + 360*tun + 20*uinal + kin

FromJulianDate может быть использована для проверки пробного ввода.

In[3]:=

example = JulianFromMayanLongCount[{7, 17, 18, 19, 2}]

Out[3]=

In[4]:=

FromJulianDate["Modified", example, TimeZone -> 0]

Out[4]=

Создайте функцию для перевода напрямую из даты календаря длинного счёта майя во временной объект по григорианскому календарю.

In[5]:=

GregorianFromMayanLongCount[date_] := DateValue[ FromJulianDate["Modified", JulianFromMayanLongCount[date], TimeZone -> 0], "Day", DateObject]

In[6]:=

GregorianFromMayanLongCount[{7, 17, 18, 19, 2}]

Out[6]=

Создайте функцию для перевода даты юлианского календаря в единицы календаря длинного счёта майя.

In[7]:=

JulianToMayanLongCount[date_] := NumberDecompose[ Floor[date - epoch], {144000, 7200, 360, 20, 1} ]

JulianDate может использоваться для перевода любой даты в дату по юлианскому календарю, которая затем вводится в JulianToMayanLongCount.

In[8]:=

DateToMayanLongCount[date_] := Block[{$TimeZone = 0}, JulianToMayanLongCount[JulianDate["Modified", date]] ]

Данная функция отныне принимает любые вводные данные и выдаёт в ответ соответствующий список дат по календарю длинного счёта майя.

In[9]:=

DateToMayanLongCount["May 4th, 2015"]

Out[9]=

In[10]:=

DateToMayanLongCount[AbsoluteTime[]]

Out[10]=

In[11]:=

DateToMayanLongCount[Today]

Out[11]=

Данные функции могут использоваться для перевода временных величин в и из календаря длинного счёта майя.

In[12]:=

DateToMayanLongCount[{1900, 1, 1}]

Out[12]=

In[13]:=

DateToMayanLongCount[{1900, 1, 1}]; GregorianFromMayanLongCount[%]

Out[13]=