Converta para o calendário maia

Identifique a época (ou data de início) para o calendário maia de contagem longa como uma data juliana.

In[1]:=

epoch = JulianDate["Modified", DateObject[{-3114, 8, 11}, TimeZone -> 0]];

Crie uma função para converter de unidades do calendário maia de contagem longa para uma data juliana.

In[2]:=

JulianFromMayanLongCount[{baktun_, katun_, tun_, uinal_, kin_}] := epoch + 144000*baktun + 7200*katun + 360*tun + 20*uinal + kin

FromJulianDate pode ser usada para testar um exemplo de input.

In[3]:=

example = JulianFromMayanLongCount[{7, 17, 18, 19, 2}]

Out[3]=

In[4]:=

FromJulianDate["Modified", example, TimeZone -> 0]

Out[4]=

Crie uma função para converter uma data juliana em unidades de calendário maia de contagem longa.

In[5]:=

GregorianFromMayanLongCount[date_] := DateValue[ FromJulianDate["Modified", JulianFromMayanLongCount[date], TimeZone -> 0], "Day", DateObject]

In[6]:=

GregorianFromMayanLongCount[{7, 17, 18, 19, 2}]

Out[6]=

Crie uma função para converter uma data juliana em unidades de calendário maia de contagem longa.

In[7]:=

JulianToMayanLongCount[date_] := NumberDecompose[ Floor[date - epoch], {144000, 7200, 360, 20, 1} ]

JulianDate pode ser usada para interpretar qualquer input de data em data juliana, que depois é inserida em JulianToMayanLongCount.

In[8]:=

DateToMayanLongCount[date_] := Block[{$TimeZone = 0}, JulianToMayanLongCount[JulianDate["Modified", date]] ]

Esta função irá agora aceitar qualquer input de data e retornará o lista correspondente de datas do calendário maia de contagem longa.

In[9]:=

DateToMayanLongCount["May 4th, 2015"]

Out[9]=

In[10]:=

DateToMayanLongCount[AbsoluteTime[]]

Out[10]=

In[11]:=

DateToMayanLongCount[Today]

Out[11]=

Estas duas funções podem ser usadas para converter de e para o calendário maia de contagem longa.

In[12]:=

DateToMayanLongCount[{1900, 1, 1}]

Out[12]=

In[13]:=

DateToMayanLongCount[{1900, 1, 1}]; GregorianFromMayanLongCount[%]

Out[13]=