Wolfram Language

Impressão 3D

Ache as orientações ideais para impressão em 3D

Com um amplo suporte para as regiões geométricas baseadas em malha, a análise de capacidade de impressão de cargas estruturais para orientação vertical é fácil de executar.

Encontre possíveis orientações para colocar o modelo em uma superfície plana.

mostre o input completo da Wolfram Language
In[1]:=
Click for copyable input
cover = TransformedRegion[ MeshRegion[ Import["http://www.thingiverse.com/download:342676", "STL"], PlotTheme -> "Minimal"], TransformationFunction[{{1., 0.5, 0.03, -0.06}, {-0.05, 0.03, 1.1, 0.1}, {0.53, -1.02, 0.05, 0.19}, {0, 0, 0, 1.}}]]; points = MeshCoordinates[cover]; transform[Polygon[points_]] := Module[{proj = points}, proj[[All, 3]] = 0; Last[FindGeometricTransform[proj, points]]]; highlight[convexHull_, cover_] := Show[HighlightMesh[ convexHull, {Style[1, Brown], Style[2, Opacity[0.3, Brown]]}], cover]; Show[cover, Boxed -> True]
Out[1]=

Cada face da envoltória convexa representa uma possível orientação.

In[2]:=
Click for copyable input
convexHull = ConvexHullMesh[points]; orientations = MeshPrimitives[convexHull, 2]; highlight[convexHull, cover]
Out[2]=

Utilize a projeção ortogonal do centro de massa para restringir ainda mais possíveis orientações.

In[3]:=
Click for copyable input
masscenter = RegionCentroid[cover]; projection[polygon_, p_] := RegionNearest[AffineSpace @@ polygon, p]; candidates = Select[orientations, RegionMember[#, projection[#, masscenter]] &];

Uma possível orientação.

In[4]:=
Click for copyable input
Show[ncover = TransformedRegion[cover, transform[Last[SortBy[candidates, Area]]]], Boxed -> True]
Out[4]=

Imprima o modelo.

In[5]:=
Click for copyable input
Printout3D[ncover, "Shapeways"]
Out[5]=

Exemplos Relacionados

de en es fr ja ko ru zh