创建并破译摩尔斯电码信号: Wolfram语言 11 的新功能

创建并破译摩尔斯电码信号

创建摩尔斯电码词典.

显示完整的 Wolfram 语言输入

In[1]:=

code = <|"a" -> ".-", "b" -> "-...", "c" -> "-.-.", "d" -> "-..", 
  "e" -> ".", "f" -> "..-.", "g" -> "--.", "h" -> "....", "i" -> "..",
   "j" -> ".---", "k" -> "-.-", "l" -> ".-..", "m" -> "--", 
  "n" -> "-.", "o" -> "---", "p" -> ".--.", "q" -> "--.-", 
  "r" -> ".-.", "s" -> "...", "t" -> "-", "u" -> "..-", "v" -> "...-",
   "w" -> ".--", "x" -> "-..-", "y" -> "-.--", "z" -> "--..", 
  "1" -> ".----", "2" -> "..---", "3" -> "...--", "4" -> "....-", 
  "5" -> ".....", "6" -> "-....", "7" -> "--...", "8" -> "---..", 
  "9" -> "----.", "0" -> "-----", "." -> ".-.-.-", "," -> "--..--", 
  "!" -> "-.-.--", "?" -> "..--.."|>
withgaps = Map[StringRiffle[Characters[#], "_"] &, code];
withpauses = Map[StringInsert[#, "___", -1] &, withgaps];
withspace = AssociateTo[withpauses, " " -> "_______"];
replacements = 
  Map[StringReplace[#, {"-" -> "111", "." -> "1", "_" -> "0"}] &, 
   withspace];

Out[1]=

创建一个函数，使用词典将信息翻译为音频信号.

In[2]:=

createMorseSignal[s_String, t_] := 
 Module[{events = 
    Characters[StringReplace[ToLowerCase[s], Normal@replacements]], 
   ts, amps},
  ts = TimeSeries[ToExpression@events, {0, (Length[events] - 1)*t, t}];
  amps = AudioGenerator[ts, SampleRate -> 1000]; 
  AudioGenerator[{"Sin", 800}, Duration@amps, 
    SampleRate -> 8000] amps
  ]

将字符串编码为音频信号.

In[3]:=

morse = createMorseSignal["hello world", .07]

Out[3]=

在对其时间不做任何推测的条件下，破译摩尔斯信号.

In[4]:=

inversecode = AssociationThread[Values[code], Keys[code]]

Out[4]=

显示完整的 Wolfram 语言输入

In[5]:=

decodeMorseSignal[audio_] := 
 Module[{rms, rounded, crossings, transients, shifted, dit},
  rms = AudioLocalMeasurements[audio, "RMSAmplitude", 
    PartitionGranularity -> {.01, .002}];
  rounded = Round[rms/Max@rms];
  crossings = 
   TimeSeriesInsert[
    TimeSeries[
     CrossingDetect[rounded["Values"] - .5, 
      CornerNeighbors -> True], {rounded["Times"]}], {0, 1}];
  transients = TimeSeries@Select[Normal@crossings, #[[2]] == 1 &];
  shifted = TimeSeriesShift[transients, -transients["FirstTime"]];
  dit = MinimumTimeIncrement[shifted]; 
  StringSplit[
    StringJoin[
     Table[{Differences[shifted["Times"]][[i]], Mod[i, 2]}, {i, 
        Length@Differences[shifted["Times"]]}] /. {{x_, 1} /; .5 dit <
           x < 1.5 dit -> ".", {x_, 1} /; 2.5 dit < x < 3.5 dit -> 
        "-", {x_, 0} /; 2.5 dit < x < 3.5 dit -> 
        "/", {x_, 0} /; .5 dit < x < 1.5 dit -> 
        Nothing, {x_, 0} /; 5 dit < x < 12 dit -> "/_/"}], "/"] /. 
   "_" -> " "
  ]

In[6]:=

decoded = decodeMorseSignal[morse]

Out[6]=

In[7]:=

StringJoin[decoded /. inversecode]

Out[7]=

Wolfram 语言™

创建并破译摩尔斯电码信号

相关范例