一目で分かる旅行記録
写真は，画素コンテンツとメタデータの両方を含むファイルとして保存することができる．Importを使ってメタデータを入手し，写真のコンテキストについてプログラム可能な内容を発見することができる．
リスボン旅行の際に撮った写真をインポートして分析する．
In[1]:=
files = Map[img \[Function] ExampleData[img, "FilePath"],
ExampleData[{"TestImageSet", "Lisbon2016"}]];画像の日付ヒストグラムを見る：
In[2]:=
dates = Map[file \[Function] Import[file, "DateTime"], files];In[3]:=
DateHistogram[dates, Quantity[1, "Hours"]]Out[3]=
サムネイルのコラージュを見る：
In[4]:=
thumbnails =
ExampleData[{"TestImageSet", "Lisbon2016"}, "ThumbnailList"];In[5]:=
ImageCollage[thumbnails, Method -> "Columns", ImagePadding -> 2]Out[5]=
写真をタイムラインに並べる．
In[6]:=
TimelinePlot[MapThread[Labeled, {dates, thumbnails}],
PlotLayout -> "Vertical", ImageSize -> Medium]Out[6]=
データ集合中のすべての情報を集める．
In[7]:=
gps = Map[file \[Function] Import[file, "GeoPosition"], files];In[8]:=
ds = Dataset[
MapThread[
AssociationThread[{"Thumbnail", "DateTime",
"GeoPosition"} -> {##}] &, {thumbnails, dates, gps}]]Out[8]=
写真が撮られた場所を表示する．
In[9]:=
GeoGraphics[
MapThread[
GeoMarker, {Normal[ds[All, "GeoPosition"]],
Normal[ds[All, "Thumbnail"]]}], ImageSize -> Medium]Out[9]=
