한눈에 떠나는 여행
사진은 화소 콘텐츠와 메타 데이터를 모두 포함하는 파일로 저장할 수 있습니다. Import를 사용하여 이러한 메타 데이터를 얻고 사진이 포함하고 있는 컨텍스트에 대해 프로그램 가능한 통찰력을 얻을 수 있습니다.
리스본 여행시 찍은 사진을 가져와서 분석합니다.
In[1]:=
files = Map[img \[Function] ExampleData[img, "FilePath"],
ExampleData[{"TestImageSet", "Lisbon2016"}]];
이미지의 날짜 히스토그램을 알아봅니다.
In[2]:=
dates = Map[file \[Function] Import[file, "DateTime"], files];
In[3]:=
DateHistogram[dates, Quantity[1, "Hours"]]
Out[3]=
섬네일 콜라주를 확인합니다.
In[4]:=
thumbnails =
ExampleData[{"TestImageSet", "Lisbon2016"}, "ThumbnailList"];
In[5]:=
ImageCollage[thumbnails, Method -> "Columns", ImagePadding -> 2]
Out[5]=
사진을 타임 라인에 정렬합니다.
In[6]:=
TimelinePlot[MapThread[Labeled, {dates, thumbnails}],
PlotLayout -> "Vertical", ImageSize -> Medium]
Out[6]=
데이터 집합의 모든 정보를 모아봅니다.
In[7]:=
gps = Map[file \[Function] Import[file, "GeoPosition"], files];
In[8]:=
ds = Dataset[
MapThread[
AssociationThread[{"Thumbnail", "DateTime",
"GeoPosition"} -> {##}] &, {thumbnails, dates, gps}]]
Out[8]=
이미지를 찍은 위치를 표시합니다.
In[9]:=
GeoGraphics[
MapThread[
GeoMarker, {Normal[ds[All, "GeoPosition"]],
Normal[ds[All, "Thumbnail"]]}], ImageSize -> Medium]
Out[9]=