Анализ хода гиперинфляции в странах Южной Америки : Новое в системе Wolfram Language 11

‹›

Анализ хода гиперинфляции в странах Южной Америки

Установить связь с Federal Reserve Economic Data API.

In[1]:=

fred = ServiceConnect["FederalReserveEconomicData"]

Out[1]=

Получить список стран Южной Америки.

In[2]:=

countries = CountryData["SouthAmerica"];

Извлечь временные ряды инфляции для выбранных стран.

In[3]:=

data = Association[DeleteMissing[Block[{source, id, ts, fts},
       source = 
        fred["SeriesSearch", 
         "Query" -> # <> "  inflation consumer price"];
              	If[Length[source] > 0,
                	(id = source[1, "ID"];
                  	ts = fred["SeriesData", "ID" -> id];
                  	
         fts = TimeSeries[ts , MissingDataMethod -> Automatic];
                  	# -> fts),
                	Missing[#]]
       		] & /@ (EntityValue[#, "Name"] & /@ countries)]];

Получить график стран с гиперинфляцией в период с 1960 по 2015 год.

код на языке Wolfram Language целиком

In[4]:=

hyperinflation = Select[data, (Max[#["Values"]] > 1000 &)];
DateListLogPlot[Thread[Legended[Values[#], Keys[#]]] &@hyperinflation,
  Filling -> Axis, FrameStyle -> White, 
 FrameLabel -> "Logscale of inflation", 
 FrameTicks -> {{Automatic, 
    None}, {Table[DateObject[{i}], {i, 1960, 2015, 5}], None}}, 
 PlotRange -> Full, Background -> RGBColor[0.25, 0.25, 0.25], 
 AspectRatio -> 1/2, DateTicksFormat -> "YearShort", ImageSize -> 480,
  GridLines -> {None, {{10, White}, {100, Pink}, {1000, Red}}}, 
 GridLinesStyle -> {Thickness[Small], Dashed}]

Out[4]=