Tiempo y distancia de viaje
Estime la distancia y duración de un viaje por carretera.
Viaje entre dos ciudades distantes.
In[1]:=
![Click for copyable input](assets.es/travel-time-and-distance/In_42.png)
cities = {Entity["City", {"Lisbon", "Lisboa", "Portugal"}],
Entity["City", {"Beijing", "Beijing", "China"}]};
Esta es una distancia geodésica entre ellas.
In[2]:=
![Click for copyable input](assets.es/travel-time-and-distance/In_43.png)
GeoDistance[cities]
Out[2]=
![](assets.es/travel-time-and-distance/O_32.png)
Esta es la distancia del viaje por carretera calculado.
In[3]:=
![Click for copyable input](assets.es/travel-time-and-distance/In_44.png)
TravelDistance[cities]
Out[3]=
![](assets.es/travel-time-and-distance/O_33.png)
Y este es el tiempo de conducción estimado, asumiendo una conducción continua, sin paradas.
In[4]:=
![Click for copyable input](assets.es/travel-time-and-distance/In_45.png)
TravelTime[cities]
Out[4]=
![](assets.es/travel-time-and-distance/O_34.png)
Este objeto contiene el conjunto real de instrucciones de viaje.
In[5]:=
![Click for copyable input](assets.es/travel-time-and-distance/In_46.png)
td = TravelDirections[{Entity[
"City", {"Lisbon", "Lisboa", "Portugal"}],
Entity["City", {"Beijing", "Beijing", "China"}]}]
Out[5]=
![](assets.es/travel-time-and-distance/O_35.png)
Represente la trayectoria (en rojo) en un mapa de Mercator, y compare con la trayectoria geodésica (en azul), la cual es más corta, como vimos anteriormente.
In[6]:=
![Click for copyable input](assets.es/travel-time-and-distance/In_47.png)
GeoGraphics[{Thick, Red, GeoPath[td], Blue,
GeoPath[{Entity["City", {"Lisbon", "Lisboa", "Portugal"}],
Entity["City", {"Beijing", "Beijing", "China"}]}]},
GeoProjection -> "Mercator", GeoGridLines -> Automatic]
Out[6]=
![](assets.es/travel-time-and-distance/O_36.png)
Una proyección acimutal muestra más claramente que la geodésica es más corta que la ruta de viaje.
In[7]:=
![Click for copyable input](assets.es/travel-time-and-distance/In_48.png)
GeoGraphics[{Thick, Red, GeoPath[td], Blue,
GeoPath[{Entity["City", {"Lisbon", "Lisboa", "Portugal"}],
Entity["City", {"Beijing", "Beijing", "China"}]}]},
GeoProjection -> "Mercator", GeoGridLines -> Automatic];
Show[%, GeoProjection -> "LambertAzimuthal", GeoZoomLevel -> 4]
Out[7]=
![](assets.es/travel-time-and-distance/O_37.png)