Alphabets incluant une lettre particulière : Nouveautés de Wolfram Language 11

Alphabets incluant une lettre particulière

À l'aide de l'Alphabet et de la liste des entités de type "Alphabet", il est facile de trouver les alphabets contenant une lettre particulière.

Essayez de trouver ceux qui ont les lettres ø, æ, ñ ou и.

In[1]:=

alphabetEntities = EntityList["Alphabet"];

In[2]:=

Select[alphabetEntities, MemberQ[Alphabet[#], "ø"] &]

Out[2]=

In[3]:=

Select[alphabetEntities, MemberQ[Alphabet[#], "æ"] &]

Out[3]=

In[4]:=

Select[alphabetEntities, MemberQ[Alphabet[#], "ñ"] &]

Out[4]=

In[5]:=

Select[alphabetEntities, MemberQ[Alphabet[#], "и"] &]

Out[5]=

Obtenez des variantes de la voyelle o en utilisant AlphabeticOrder.

In[6]:=

lettersO = 
 Select[CharacterRange[1, 65535], 
  AlphabeticOrder["o", #, IgnoreDiacritics -> True, 
     IgnoreCase -> False] == 0 &]

Out[6]=

Créez une fonction pour extraire les langues contenant une lettre particulière.

In[7]:=

alphabets = Alphabet /@ alphabetEntities;
getAlphabet[letter_] := 
  Pick[alphabetEntities, MemberQ[#, letter] & /@ alphabets];

Affichez les variantes de la voyelle o et de leurs alphabets.

Afficher l'entrée complète de Wolfram Language

In[8]:=

TextGrid[DeleteCases[{#, Row@getAlphabet[#]} & /@ Rest[lettersO] , {_,
    Row@{}}], Frame -> All, Alignment -> {Left, Center}]

Out[8]=