Dele seguimiento a la popularidad de los nombres: Nuevo en Wolfram Language 11

Dele seguimiento a la popularidad de los nombres

Obtenga los nombre más populares de niñas y su posicionamiento en el tiempo.

In[1]:=

girls = SortBy[
  EntityList[
   EntityClass[
    "GivenName", {"Gender" -> "Female", 
     "Rank" -> Interval[{1, 10}]}]], #["Rank"] &]

Out[1]=

In[2]:=

ranksgirls = 
  Table[EntityValue[name, 
    Dated[EntityProperty["GivenName", "Rank"], All]], {name, girls}];

Represente gráficamente las clasificaciones de los últimos 50 años en una escala logarítmica que presente el nombre más popular en la parte superior.

In[3]:=

DateListStepPlot[ranksgirls, 
 ScalingFunctions -> {-Log[#] &, Exp[-#] &}, PlotLegends -> girls, 
 PlotTheme -> "Business", ImageSize -> 475, 
 PlotRange -> {{DateObject[{1965}], DateObject[{2015}]}, All}]

Out[3]=

In[4]:=

boys = SortBy[
   EntityList[
    EntityClass[
     "GivenName", {"Gender" -> "Male", 
      "Rank" -> Interval[{1, 10}]}]], #["Rank"] &];

In[5]:=

ranksboys = 
  Table[EntityValue[name, 
    Dated[EntityProperty["GivenName", "Rank"], All]], {name, boys}];

Viendo las clasificaciones de nombres de niños, se puede ver que algunos nombres han sido consistentemente populares en el tiempo.

In[6]:=

DateListStepPlot[ranksboys, 
 ScalingFunctions -> {-Log[#] &, Exp[-#] &}, PlotLegends -> boys, 
 PlotTheme -> "Business", ImageSize -> 475, 
 PlotRange -> {{DateObject[{1965}], DateObject[{2015}]}, All}]

Out[6]=