Rastreie a popularidade dos nomes: Novos Recursos do Wolfram Language 11

Rastreie a popularidade dos nomes

Obtenha os nomes mais populares para meninas e as suas classificações ao longo do tempo.

In[1]:=

girls = SortBy[
  EntityList[
   EntityClass[
    "GivenName", {"Gender" -> "Female", 
     "Rank" -> Interval[{1, 10}]}]], #["Rank"] &]

Out[1]=

In[2]:=

ranksgirls = 
  Table[EntityValue[name, 
    Dated[EntityProperty["GivenName", "Rank"], All]], {name, girls}];

Faça o gráfico dos rankings para os últimos 50 anos em uma escala logarítmica que tenha o nome mais popular no topo.

In[3]:=

DateListStepPlot[ranksgirls, 
 ScalingFunctions -> {-Log[#] &, Exp[-#] &}, PlotLegends -> girls, 
 PlotTheme -> "Business", ImageSize -> 475, 
 PlotRange -> {{DateObject[{1965}], DateObject[{2015}]}, All}]

Out[3]=

In[4]:=

boys = SortBy[
   EntityList[
    EntityClass[
     "GivenName", {"Gender" -> "Male", 
      "Rank" -> Interval[{1, 10}]}]], #["Rank"] &];

In[5]:=

ranksboys = 
  Table[EntityValue[name, 
    Dated[EntityProperty["GivenName", "Rank"], All]], {name, boys}];

Olhando para o ranking de nomes de meninos vemos que alguns nomes têm sido constantemente populares ao longo do tempo.

In[6]:=

DateListStepPlot[ranksboys, 
 ScalingFunctions -> {-Log[#] &, Exp[-#] &}, PlotLegends -> boys, 
 PlotTheme -> "Business", ImageSize -> 475, 
 PlotRange -> {{DateObject[{1965}], DateObject[{2015}]}, All}]

Out[6]=