Trace la densidad de los libros de bibliotecas en los Estados Unidos 

Trace la distribución de la densidad espacial de los libros de bibliotecas en los Estados Unidos.

muestre la entrada completa de Wolfram Languageoculte la entrada

In[1]:=

X allLibraries = EntityValue["PublicLibrary", "Entities"];

In[2]:=

X cities = EntityValue[allLibraries, EntityProperty["PublicLibrary", "City"]];

In[3]:=

X books = EntityValue[allLibraries, EntityProperty["PublicLibrary", "Books"]];

In[4]:=

X booksInTheCities = {#[[1, 1]], Total[Last /@ #]} & /@ GatherBy[ Select[Transpose[{cities, books}], FreeQ[#, _Missing, \[Infinity]] &], First];

In[5]:=

X coords = EntityValue[(First /@ booksInTheCities), "Position"];

In[6]:=

X booksAndPositions = Transpose[{coords, Last /@ booksInTheCities}];

In[7]:=

X projection = {"LambertAzimuthal", "Centering" -> GeoPosition[{37.1558, -95.883}]};

In[8]:=

X data = {GeoGridPosition[#1, projection][[1]], #2} & @@@ booksAndPositions;

In[9]:=

X weightedData = WeightedData @@ Transpose[Take[data, All]];

In[10]:=

X bookDensityP = SmoothKernelDistribution[weightedData, "Silverman"];

In[11]:=

X bookDensity[{lat_Real, long_Real}] := With[{xy = First[GeoGridPosition[GeoPosition[{lat, long}], projection]]}, Flatten[{xy, PDF[bookDensityP, xy]}]];

In[12]:=

X USA = GeoVariant[Entity["Country", "UnitedStates"], "ContiguousArea"];

In[13]:=

X {{latmin, latmax}, {longmin, longmax}} = GeoBounds[USA];

In[14]:=

X bookPlot = ContourPlot[ Sqrt[Last[bookDensity[{lat, long}]]], {long, longmin, longmax}, {lat, latmin, latmax}, Frame -> False, PlotRange -> All, Contours -> 100, MaxRecursion -> 2, ColorFunction -> ColorData["DarkRainbow"], PlotRangePadding -> 0, ContourStyle -> None];

In[15]:=

X GeoGraphics[{GeoStyling[{"GeoImage", bookPlot}], Polygon[USA], GrayLevel[0.3], Opacity[1], PointSize[0.001], Point[coords]}, GeoRange -> USA]

Out[15]=