‹›クラウドおよびWebのインターフェース天候の概要を示す人気のあるWebページをキャッシュに保存する
評価が遅延された(Delayed)クラウドオブジェクトが,再計算が必要となる前に多数の人々によって閲覧されるようなら,CachePersistenceオプションを使って,その出力を一定期間キャッシュに保存することができる.
前週のリオデジャネイロの気温履歴を計算する関数を定義する.
完全なWolfram言語入力を表示する
rioTemperatureHistory[] :=
With[{temps =
AirTemperatureData[
GeoPosition[
Entity["City", {"RioDeJaneiro", "RioDeJaneiro",
"Brazil"}]], {Now - Quantity[1, "Weeks"], Now}]},
labelcolor = GrayLevel[0.4];
tempcolor = GrayLevel[0.4];
grid = Grid[{{Style["Current", labelcolor],
Row[{Style[
QuantityForm[Round@Last[temps["Values"]], "Abbreviation"],
tempcolor], " "}]}, {Style["High", labelcolor],
Row[{Style[
QuantityForm[Round@Max[temps["Values"]], "Abbreviation"],
tempcolor], " "}]}, {Style["Low", labelcolor],
Row[{Style[
QuantityForm[Round@Min[temps["Values"]], "Abbreviation"],
tempcolor], " "}]}}, Alignment -> {{Right, Left}}];
table =
Style[Column[{Row[{"Past Week "}, Alignment -> {Bottom, Right}
], grid}, Alignment -> Right], 16, RGBColor[
0.9098049191388243, 0.3176450101594796, 0.24313742164725222`]];
DateListPlot[temps, PlotRange -> {55, 100},
AxesLabel -> Style["\[Degree]F", 20, Black],
TicksStyle -> Directive[Black, 14], Ticks -> {None, Automatic},
PlotStyle -> Directive[AbsoluteThickness[2], Black],
Filling -> Bottom,
FillingStyle ->
Directive[RGBColor[
0.9098049191388243, 0.3176450101594796, 0.24313742164725222`],
Opacity[1]],
Epilog -> Inset[table, Scaled[{0.95, 0.9}], {Right, Top}],
PlotTheme -> {"Wide", "Presentation"}, ImageSize -> 550]]
rioTemperatureHistory[]
結果を5分間キャッシュに保存する関数をアプリケーションとして配備する.これで何千ものユーザが同時にこのアプリケーションにアクセスしても,ユーザ側はかなり新しい情報を得ることができる一方で,サーバ側は毎回再計算する必要がないため応答時間が速くなり,サーバへの負荷も低くなる.
obj = CloudDeploy[
Delayed[rioTemperatureHistory[], "PNG",
CachePersistence -> Quantity[5, "Minutes"]]]